3

我想测试一个属性，我使用 2 个概率率 p1 和 p2 必须满足 0 < p1 < p2 < 1

let arraySizeCheck (p1:float, p2:float, xs:list<int>) =
(p1 < p2 && p1 > 0.0 && p1 < 1.0 && p2 > 0.0 && p2 < 1.0 && Seq.length xs > 0) ==>
(lazy
    (
        let bf1 = BloomFilter(p1, xs)
        let bf2 = BloomFilter(p2, xs)
        bf2.BitArraySize < bf1.BitArraySize
    )
)

Check.Quick arraySizeCheck

我已经尝试了上面的例子，但测试结果似乎是

0 次测试后参数耗尽。验证它：单位=（）

此外，我希望列表 xs 不包含重复项。任何有助于为此属性编写测试的帮助将不胜感激。谢谢。

4

1 回答 1

2

更惯用的方法是使用模块中的gen计算表达式和组合函数Gen。不幸的是，返回生成随机浮点数的生成器的函数被隐藏了（参见源代码。）

但是我们可以创建自己的：

open System
open FsCheck
open FsCheck.Gen
open FsCheck.Prop

/// Generates a random float [0..1.0]
let rand = Gen.choose (0, Int32.MaxValue) |> Gen.map (fun x -> double x / (double Int32.MaxValue))

/// Generates a random float in the given range (inclusive at both sides)
let randRange a b = rand |> Gen.map (fun x -> a + (b - a) * x)

let arraySizeCheck =
    Prop.forAll
        (Arb.fromGen <| gen {
            // generate p1 and p2 such that 0 <= p1 <= p2 <= 1
            let! p1 = randRange 0.0 1.0
            let! p2 = randRange p1 1.0

            // generate non-empty Seq<int>
            let! xs = Gen.nonEmptyListOf Arb.generate<int> |> Gen.map Seq.ofList

            return BloomFilter(p1, xs), BloomFilter(p2, xs)
        })
        (fun (bf1, bf2) -> bf2.BitArraySize < bf1.BitArraySize)

Check.Quick arraySizeCheck

请注意p1和p2这里 是这样生成的0 <= p1 <= p2 <= 1，这并不完全是您所需要的。但我认为对rand函数进行简单的修改就可以解决这个问题。

于 2014-09-09T08:22:29.350 回答