opengl - 如何访问 GLSL 片段着色器纹理中的自动 mipmap 级别？

Question

在 GLSL 片段着色器中对纹理进行采样时，如何确定使用的 mipmap 级别？

我知道我可以使用以下textureLod(...)方法手动采样纹理的特定 mipmap 级别：

uniform sampler2D myTexture;

void main()
{
    float mipmapLevel = 1;
    vec2 textureCoord = vec2(0.5, 0.5);
    gl_FragColor = textureLod(myTexture, textureCoord, mipmapLevel);
}

texture(...)或者我可以允许使用like自动选择 mipmap 级别

uniform sampler2D myTexture;

void main()
{
    vec2 textureCoord = vec2(0.5, 0.5);
    gl_FragColor = texture(myTexture, textureCoord);
}

我更喜欢后者，因为我更相信驱动程序对适当 mipmap 级别的判断，而不是我自己的判断。

但是我想知道在自动采样过程中使用了什么mipmap级别，以帮助我合理地采样附近的像素。GLSL 中有没有办法访问有关自动纹理样本使用的 mipmap 级别的信息？

score 30 · Accepted Answer

以下是解决此问题的三种不同方法，具体取决于您可以使用哪些 OpenGL 功能：

正如Andon M. Coleman在评论中指出的，OpenGL 4.00 及以上版本的解决方案很简单；只需使用以下textureQueryLod功能：

#version 400

uniform sampler2D myTexture;
in vec2 textureCoord; // in normalized units
out vec4 fragColor;

void main()
{
    float mipmapLevel = textureQueryLod(myTexture, textureCoord).x;
    fragColor = textureLod(myTexture, textureCoord, mipmapLevel);
}

在早期版本的 OpenGL（2.0+？）中，您可能能够加载扩展，以达到类似的效果。这种方法适用于我的情况。注意：方法调用在扩展中的大写不同，与内置（queryTextureLodvs queryTextureLOD）不同。

#version 330

#extension GL_ARB_texture_query_lod : enable

uniform sampler2D myTexture;
in vec2 textureCoord; // in normalized units
out vec4 fragColor;

void main()
{
    float mipmapLevel = 3; // default in case extension is unavailable...
#ifdef GL_ARB_texture_query_lod
    mipmapLevel = textureQueryLOD(myTexture, textureCoord).x; // NOTE CAPITALIZATION
#endif
    fragColor = textureLod(myTexture, textureCoord, mipmapLevel);
}

如果加载扩展不起作用，您可以使用genpfault提供的方法估计自动详细程度：

#version 330

uniform sampler2D myTexture;
in vec2 textureCoord; // in normalized units
out vec4 fragColor;

// Does not take into account GL_TEXTURE_MIN_LOD/GL_TEXTURE_MAX_LOD/GL_TEXTURE_LOD_BIAS,
// nor implementation-specific flexibility allowed by OpenGL spec
float mip_map_level(in vec2 texture_coordinate) // in texel units
{
    vec2  dx_vtc        = dFdx(texture_coordinate);
    vec2  dy_vtc        = dFdy(texture_coordinate);
    float delta_max_sqr = max(dot(dx_vtc, dx_vtc), dot(dy_vtc, dy_vtc));
    float mml = 0.5 * log2(delta_max_sqr);
    return max( 0, mml ); // Thanks @Nims
}

void main()
{
    // convert normalized texture coordinates to texel units before calling mip_map_level
    float mipmapLevel = mip_map_level(textureCoord * textureSize(myTexture, 0));
    fragColor = textureLod(myTexture, textureCoord, mipmapLevel);
}

无论如何，对于我的特定应用程序，我最终只是在主机端计算 mipmap 级别，并将其传递给着色器，因为自动详细级别结果并不是我所需要的。

score 14 · Accepted Answer

从这里：

查看OpenGL 4.2 规范第 3.9.11 章等式 3.21。基于导数向量的长度计算mip map级别：

float mip_map_level(in vec2 texture_coordinate)
{
    vec2  dx_vtc        = dFdx(texture_coordinate);
    vec2  dy_vtc        = dFdy(texture_coordinate);
    float delta_max_sqr = max(dot(dx_vtc, dx_vtc), dot(dy_vtc, dy_vtc));
    return 0.5 * log2(delta_max_sqr);
}

opengl - 如何访问 GLSL 片段着色器纹理中的自动 mipmap 级别？

2 回答 2

Related

Reference