7

我正在使用 Mercurial（特别是 Windows 上的 TortoiseHg）对 VBA 代码进行版本控制。任何尝试过这个的人都知道，只要在项目中的任何地方更改了该变量的任何声明（无论范围如何），VBA 都会更改整个项目中每个变量的大小写。它使版本控制成为一场噩梦。

我想在执行 diffs 时忽略源代码中的大小写更改。最简单的方法是什么？（我缺少的 diff 选项，外部 diff 实用程序，还有别的吗？）

注意：我不是在谈论处理“不区分大小写的文件名”（是的，我在和你说话谷歌......）

4

3 回答 3

7

您可以在使用ExtDiff Extension为您的屏幕消费进行差异化时做到这一点。

  [extensions]
  hgext.extdiff =

  [extdiff]
  # add new command that runs GNU diff(1) in case-insensitive mode
  cmd.mydiff = diff
  opts.mydiff = -i

然后你会从命令行运行hg mydiff。当然，这需要您安装 diff 二进制文件，无论是 gnu 还是其他。

但是，这不会像您希望的那样有用，因为在内部，当然，Mercurial 不能忽略大小写——它采用文件内容的加密哈希，而那些不允许回旋余地。因此，如果您进行此设置，您将执行此操作hg mydiff，但看不到任何更改，然后执行hg commit并查看所有更改。

所以你可以在屏幕上进行这项工作，但不是从根本上。

一种选择是找到一个类似于indentC 语言的 Visual Basic 代码清理器，它可以规范化变量大小写并在 mercurial 提交挂钩中运行它。然后至少所有进入源代码控制的代码都是一致的，你可以准确地区分不同的版本。

于 2010-03-05T22:50:46.727 回答
2

例如，如果您可以将代码全部小写，那么您可以为此使用编码/解码钩子。它会像这样工作：

[encode]
*.vba = tr A-Z a-z

每当您进行提交时，这都会以小写形式对文件内容进行编码。差异也是根据文件的编码（存储库）版本计算的。

考虑一个包含

hello

在您的工作副本中将其更改为

Hello World

将给出一个差异

% hg diff
diff --git a/a.txt b/a.txt
--- a/a.txt
+++ b/a.txt
@@ -1,1 +1,1 @@
-hello
+hello world

注意大写的“H”和“W”是如何被忽略的。

我对 VBA 代码一无所知，所以我不能 100% 确定该解决方案是否适合您。但我希望这可以作为一个起点。

一个缺点是您需要为所有存储库设置此编码规则。repossettings扩展可以在这里为您提供帮助。

于 2010-03-06T22:15:49.820 回答
2

这是我已经确定的解决方案。它远非理想，但比我考虑过的其他选择要好。

我创建了一个 Autohotkey 脚本，它执行以下操作：

  • 将存储库中检测到更改的 MS Access 文件还原为 .orig 文件
  • 读取 .orig 文件（有更改的文件）
  • 读取现有文件（存储库中已存在的文件）
  • 将两个文件的文本转换为小写
  • 比较文件的小写内容
  • 如果文件仍然不同，则恢复 .orig 文件，以便将其提交到存储库
  • 如果文件相同（即，它们仅在大小写不同时，.orig 文件将被删除，因为我们不关心这些更改）

对于具有我们关心的实际更改的文件，我仍然可以看到所做的案例更改。如果这会导致很多噪音，我会在允许不区分大小写比较的比较工具中打开文件（例如，kdiff）。

这不是一个完美的解决方案，但它为我消除了大约 90% 的挫败感。

这是我的脚本。请注意，该脚本包括另一个 Autohotkey 脚本 ConsoleApp.ahk，它提供了一个名为ConsoleApp_RunWait(). 这是一个 3rd 方脚本，它不再适用于 64 位 AHK，所以我没有将它作为我的答案的一部分。任何执行命令行并将输出作为字符串返回的 AHK 函数就足够了。

; This script checks an MS Access source directory and reverts all files whose only modifications are to the 
; case of the characters within the file.

#Include %A_ScriptDir%\ConsoleApp.ahk
#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

; Allow for custom path to hg (support for moving to TortoiseHg 2.0)
IniRead hg, %A_ScriptDir%\LocalSettings\Settings.cfg, TortoiseHg, hg_path, hg

if 0 < 1  ; The left side of a non-expression if-statement is always the name of a variable.
{
    MsgBox Usage:`n`HgIgnoreCase DirectoryWithFilesToScrub
    ExitApp
}

SrcDir = %1%
StringReplace SrcDir, SrcDir, ", , All

StringRight test, SrcDir, 1 ; add trailing slash if necessary
ifnotequal test, \
    SrcDir = %SrcDir%\

RestoreOriginals(SrcDir)
RevertCaseChangeModifiedFiles(SrcDir)

RevertCaseChangeModifiedFiles(SrcDir) {
global hg
    includes =  -I "*.form" -I "*.bas" -I "*.report" -I "*.table"
    cmdline = %hg% revert --all %includes%

    ;Don't revert items that have been removed completely
    Loop 3
    {
        Result := ConsoleApp_RunWait(hg . " status -nrd " . includes, SrcDir)
        If (Result)
            Break
    }
    Loop parse, Result, `n, `r
    {
        if (A_LoopField)
            cmdline = %cmdline% -X "%A_LoopField%"
    }
    Result =
    ;msgbox %cmdline%
    ;revert all modified forms, reports, and code modules
    Loop 3
    {

        Result := ConsoleApp_RunWait(cmdline, SrcDir)
        If (Result)
            Break
    }
    ;MsgBox %Result%

    Loop parse, Result, `n, `r
    {
        StringLeft FileStatus, A_LoopField, 9
        If (FileStatus = "reverting")
        {
            StringMid FName, A_LoopField, 11
            FullPath = %SrcDir%%FName%
            ToolTip Checking %FullPath%
            RestoreIfNotEqual(FullPath, FullPath . ".orig")
        }
    }
    ToolTip
}

RestoreIfNotEqual(FName, FNameOrig) {
    FileRead File1, %FName%
    FileRead File2, %FNameOrig%

    StringLower File1, File1
    StringLower File2, File2
    ;MsgBox %FName%`n%FNameOrig%
    If (File1 = File2)
        FileDelete %FNameOrig%
    Else
        FileMove %FNameOrig%, %FName%, 1
}

RestoreOriginals(SrcDir) {
    Loop %SrcDir%*.orig
    {
        ;MsgBox %A_LoopFileLongPath%`n%NewName%
        NewName := SubStr(A_LoopFileLongPath, 1, -5)
        FileMove %A_LoopFileLongPath%, %NewName%, 1
    }
    while FileExist(SrcDir . "*.orig")
        Sleep 10
}
于 2015-10-13T14:57:12.257 回答