2

我正在使用 TCP/IP 协议在 Delphi XE2 中处理 DataSnap 项目，该协议需要将二进制数据流作为方法参数传递给服务器。我遇到的问题是流内容的大小限制似乎约为 32 KB。超出此限制，服务器接收到的流为空。如果我传递其他方法参数，它们会完好无损地到达，所以这似乎是参数级别的问题。

以下是 DataSnap 服务类的声明方式：

  TDataSnapTestClient = class(TDSAdminClient)
  private
    FSendDataCommand: TDBXCommand;
  public
    constructor Create(ADBXConnection: TDBXConnection); overload;
    constructor Create(ADBXConnection: TDBXConnection; AInstanceOwner: Boolean); overload;
    destructor Destroy; override;
    procedure SendData(Data: TStream);
  end;

我使用的方法应该有效，至少根据 Jim Tierney 的文章。也就是说，自 Delphi 2009 以来显然发生了一些更改，这些更改破坏了 Jim Tierney 的示例代码。

DataSnap 服务器方法流参数

任何有关如何解决此问题的想法将不胜感激。

4

2 回答 2

9

DataSnap 以 32k 块传输数据。在所有块重新组装之前，接收端无法知道将接收多少字节。接收到所有数据后，DataSnap 不会设置TStream接收数据的大小，因此在将其移动到另一个知道流中有多少字节的流之前，您无法使用它。

我知道从 DataSnap 服务器中提取 32k+ 与将 32k+ 推送到 DataSnap 服务器不同，但这也可能对您有用。TStream在 DataSnap 服务器完成接收数据后，尝试运行此代码：

procedure CopyStreamToMemoryStream(const ASource: TStream; var ADest: TMemoryStream; const Rewind: Boolean = True);
const
  LBufSize = $F000;
var
  LBuffer: PByte;
  LReadCount: Integer;
begin
  GetMem(LBuffer, LBufSize);
  ADest.Clear;
  try
    repeat
      LReadCount := ASource.Read(LBuffer^, LBufSize);
      if LReadCount > 0 then
        ADest.WriteBuffer(LBuffer^, LReadCount);
    until LReadCount < LBufSize;
  finally
    FreeMem(LBuffer, LBufSize);
  end;
  if Rewind then
    ADest.Seek(0, TSeekOrigin.soBeginning);
end;

我不记得我在哪里找到了这个代码（几年前），所以我不能在应得的地方给予信任，但它多年来一直可靠地为我工作。

于 2012-08-23T19:55:39.683 回答
0

我开始考虑它，我突然想到将数据传输到另一个内存流只会浪费内存，尤其是在文件非常大的情况下。我们需要做的就是计算字节数并设置流大小，对吧？！

procedure FixStream(const AStream: TStream);
const
  LBufSize = $F000;
var
  LBuffer: PByte;
  LReadCount, StreamSize: Integer;
begin
  GetMem(LBuffer, LBufSize);
  try
    StreamSize := 0;
    repeat
      LReadCount := AStream.Read(LBuffer^, LBufSize);
      Inc(StreamSize, LReadCount);
    until LReadCount < LBufSize;
    AStream.Size := StreamSize;
  finally
    FreeMem(LBuffer, LBufSize);
  end;
end;

你想试试吗？我现在无法测试代码，否则我会......

于 2012-08-24T01:38:18.597 回答