perl - 在 Perl 中，如何从库中导入哈希？

Question

我有一个文件revs.pm：

my %vers = ( foo => "bar" );

还有另一个文件，例如importer.pl：

use revs;

我如何%vers访问importer.pl？

Answer 1

创建一个适当的模块并将my关键字更改为我们的：

# revs.pm
package revs;

our %vers = ( foo => "bar" );

1; # Perl modules need to return a boolean "true" value.

# importer.pl
use revs;

print $revs::vers{foo} . "\n";

Answer 2

另一种常规方法是使用包中的Exporter模块，并导出变量：

package revs;
use strict;
use warnings;
require Exporter;
our @ISA    = qw(Exporter);
our @EXPORT = qw(%vers);
our %vers   = (foo=>'bar');
1;

这避免了在引用来自的变量时必须使用包名称importer.pl：

use strict;
use warnings;
use Data::Dumper;
use revs;
print Dumper(\%vers);

一个缺点是您必须确保您的变量名称是唯一的，以避免名称冲突。

Answer 3

或者，您可以不将程序的某些部分与全局变量结合起来。考虑在一个模块中使用此哈希时会发生什么：

package Foo;
use MyApp::Versions qw(%versions); # i'm going to pretend that you didn't call the module "revs".

some_function {
    while(my ($k, $v) = each %versions){
       return if $some_condition;
    }
}

然后在其他一些模块中：

package Bar;
use MyApp::Versions qw(%versions);

some_other_function {
    while(my ($k, $v) = each %versions){
       print "$k => $v\n";
    }
}

然后使用这两个模块：

use Foo;
use Bar;

some_other_function;
some_function;
some_other_function;

取决于$some_condition， some_other_function 每次调用时都会产生不同的结果。玩得开心调试。（这each比全局状态问题更多；但是通过公开内部实现，您允许调用者做您不打算做的事情，这很容易破坏您的程序。）

例如，当您将硬编码的哈希更改为按需数据库查找时，重写 Foo 和 Bar 也是一种痛苦。

所以真正的解决方案是设计一个适当的 API，并导出它而不是整个变量：

package MyApp::Versions;
use strict;
use Carp qw(confess);
use Sub::Exporter -setup => {
    exports => ['get_component_version'],
};

my %component_versions = ( foo => 42 ); # yes, "my", not "our".

sub get_component_version {
    my ($component) = @_;
    return $component_versions{$component} ||
        confess "No component $component!"
}

1;

现在您的模块更易于使用：

package Foo;
use MyApp::Versions qw(get_component_version);

sub some_function {
    die 'your foo is too old'
        unless get_component_version('foo') >= 69;

    return FooComponent->oh_hai;
}

现在 some_function 不能搞乱 some_other_function，当你改变 get_component_version 的实现时，你程序的其余部分就不管了。