2

考虑以下 Haskell 代码：

import Control.Monad.State

test :: Int -> [(Int, Int)]
test = runStateT $ do
    a <- lift [1..10]
    modify (+a)
    return a

main = print . test $ 10

这会产生以下输出：

[(1,11),(2,12),(3,13),(4,14),(5,15),(6,16),(7,17),(8,18),(9,19),(10,20)]

但是，我想生成以下输出：

[(1,11),(2,13),(3,16),(4,20),(5,25),(6,31),(7,38),(8,46),(9,55),(10,65)]

用 JavaScript 这样的不纯语言很容易做到这一点：

function test(state) {
    var result = [];

    for (var a = 1; a <= 10; a++) {
        result.push([a, state += a]);
    }

    return result;
}

你如何在 Haskell 中做同样的事情？

4

2 回答 2

6

Haskell 类型和您的 JavaScript 代码的逻辑不匹配：JS 代码在状态中有两个值（Int 和返回的列表）。相比之下，StateT Int [] a该州并没有真正的清单；相反，它多次运行有状态操作（每次运行的初始状态不变）并将所有结果收集到一个列表中。

换句话说，JS 代码有 type State (Int, [(Int, Int)]) [(Int, Int)]。但是这个翻译太直白了，我们可以写出更优雅的 Haskell 代码。

坚持使用Statemonad，我们可以使用mapMor返回一个列表forM：

test2 :: Int -> [(Int, Int)]
test2 = evalState $ 
    forM [1..10] $ \a -> do
        s <- get <* modify (+a)
        return (a, s)

一些lens魔法可以使它更类似于 JS 代码：

{-# LANGUAGE TupleSections #-}

import Control.Lens

test3 :: Int -> [(Int, Int)]
test3 = evalState $ 
    forM [1..10] $ \a -> (a,) <$> (id <+= a)

但是，我们可以State完全取消，我认为这是最好的方法：

import Control.Monad (ap)

test4 :: Int -> [(Int, Int)]
test4 n = ap zip (tail . scanl (+) n) [1..10]
-- or without ap : zip [1..10] (drop 1 $ scanl (+) n [1..10])
于 2014-04-06T10:00:01.133 回答
0

您的系列是二次的，可以更简单地生成：

series = fmap (\x -> (x, quot (x*x + x) 2 + 10)) [1..]

如果你想要一个递归关系，你可以这样写：

series :: [(Int,Int)]
series = let
  series' x y = (x, x + y) : series' (x + 1) (x + y)
  in series' 1 10

我没有看到使用单子的令人信服的理由。

于 2014-04-06T09:43:10.313 回答