xpath - XPath“之前的兄弟姐妹”

Question

我正在尝试使用 XPath 1.0（或者可能使用正则表达式）选择元素 (a)，这些元素遵循特定元素 (b) 的同级元素，但仅在另一个 b 元素之前。

<img><b>First</b><br>&nbsp;&nbsp;
<img>&nbsp;&nbsp;<a href="/first-href">First Href</a> - 19:30<br>
<img><b>Second</b><br>&nbsp;&nbsp;
<img>&nbsp;&nbsp;<a href="/second-href">Second Href</a> - 19:30<br>
<img>&nbsp;&nbsp;<a href="/third-href">Third Href</a> - 19:30<br>

我试图使样本尽可能接近真实世界。所以在这种情况下，当我在元素

<b>First</b>

我需要选择

<a href="/first-href">First Href</a> 

当我在

<b>Second</b> 

我需要选择

<a href="/second-href">Second Href</a> 
<a href="/third-href">Third Href</a>

知道如何实现吗？谢谢！

Answer 1

动态创建这个 XPath：

following-sibling::a[preceding-sibling::b[1][.='xxxx']]

其中 'xxxx' 被替换为当前<b>.

这是假设所有元素实际上都是兄弟姐妹。如果不是，您可以尝试使用preceding和following轴，或者您编写更具体的 XPath，它更类似于文档结构。

在 XSLT 中，您还可以使用：

following-sibling::a[
  generate-id(preceding-sibling::b[1]) = generate-id(current())
]

Answer 2

这是一个解决方案，它只是一个 XPath 表达式。

使用Kaysian 公式计算两个节点集$ns1和的交集$ns2：

  $ns1[count(. | $ns2) = count($ns2)]

我们简单地替换$ns1为<a>当前<b>节点之后的兄弟节点集，并替换为下一个节点之前的兄弟$ns2节点集。<a><b>

这是一个使用 this 的完整转换：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

  <xsl:template match="/">
   <xsl:apply-templates select="*/b"/>
  </xsl:template>

  <xsl:template match="b">
    At: <xsl:value-of select="."/>

    <xsl:variable name="vNextB" select="following-sibling::b[1]"/>

    <xsl:variable name="vA-sAfterCurrentB" select="following-sibling::a"/>

    <xsl:variable name="vA-sBeforeNextB" select=
    "$vNextB/preceding-sibling::a
    |
     $vA-sAfterCurrentB[not($vNextB)]
    "/>

    <xsl:copy-of select=
     "$vA-sAfterCurrentB
              [count(.| $vA-sBeforeNextB)
              =
               count($vA-sBeforeNextB)
               ]
    "/>
  </xsl:template>
</xsl:stylesheet>

当此转换应用于以下 XML 文档时：

<t>
    <img/>
    <b>First</b>
    <br />&#xA0;&#xA0;
    <img/>&#xA0;&#xA0;
    <a href="/first-href">First Href</a> - 19:30
    <br />
    <img/>
    <b>Second</b>
    <br />
    <img/>&#xA0;&#xA0;
    <a href="/second-href">Second Href</a> - 19:30
    <br />
    <img/>&#xA0;
    <a href="/third-href">Third Href</a> - 19:30
    <br />
</t>

产生正确的结果：

   At: First <a href="/first-href">First Href</a>
    At: Second <a href="/second-href">Second Href</a>
<a href="/third-href">Third Href</a>