1

我正在尝试在我的 LG G2 上使用 HCE，并使用 Elechouse NFC 模块 2.0 向 Arduino Uno 发送一些数据。

问题是nfc.inDataExchange(selectApdu, sizeof(selectApdu), response, &responseLength)总是返回false。怎么了？

在Arduino 论坛上，MisterFrench 让它工作了，我正在使用完全相同的原理做事。我从 Android HCE 示例中获取了以下内容，并发送了一些垃圾数据：

@Override
public byte[] processCommandApdu(byte[] commandApdu, Bundle extras) {
    Log.i(TAG, "Received APDU: " + ByteArrayToHexString(commandApdu));
    // If the APDU matches the SELECT AID command for this service,
    // send the loyalty card account number, followed by a SELECT_OK status trailer (0x9000).
    if (Arrays.equals(SELECT_APDU, commandApdu)) {

        StringBuilder stringBuilder = new StringBuilder();
        stringBuilder.append(Build.MANUFACTURER);
        stringBuilder.append("#");
        stringBuilder.append(Build.MODEL);
        stringBuilder.append(((TelephonyManager)getSystemService(Context.TELEPHONY_SERVICE)).getDeviceId());
        String data = stringBuilder.toString();
        Log.i(TAG, "Data send");

        return ConcatArrays(data.getBytes(), SELECT_OK_SW);
    } else {
        return UNKNOWN_CMD_SW;
    }
}

在 Arduino 方面，我从 Arduino 论坛获取代码并稍作修改。现在看起来像

void loop(void) {
    bool success;
    Serial.println("Waiting for an ISO14443A card");

    success = nfc.inListPassiveTarget();
    if(success) {
        Serial.println("Found something!");
        uint8_t selectApdu[] = { 
          0x00, /* CLA */
          0xA4, /* INS */
          0x04, /* P1  */
          0x00, /* P2  */
          0x05, /* Length of AID  */
          0xF2, 0x22, 0x22, 0x22, 0x22,
          0x00  /* Le  */};

        uint8_t response[256];
        uint8_t responseLength = sizeof(response);

        success = nfc.inDataExchange(selectApdu, sizeof(selectApdu), response, &responseLength);

        if(success) {
            Serial.print("RAW: ");
            for (int i = 0; i < responseLength; ) {
                Serial.print(response[i++]);
                Serial.print(" ");
            }
            Serial.println(" ");

            for (int i = 0; i < responseLength; i++) {
                Serial.print((char)response[i]);
                Serial.print(" ");
            }
            Serial.println(" ");
        }
        else{
            Serial.println("Failed sending SELECT AID"); 
        }
    }
    else {
        Serial.println("Didn't find anything!");
    }
    delay(1000);
}

我正在使用来自https://github.com/elechouse/PN532的 Arduino UNO、NFC 库“PN532”

4

2 回答 2

0

显然这些行会导致问题：

uint8_t response[256];
uint8_t responseLength = sizeof(response);

success = nfc.inDataExchange(selectApdu, sizeof(selectApdu), response, &responseLength);

在第一行中，您创建了一个 256 字节的数组。在下一行中，将该数组的大小分配给一个 8 位无符号整数 ( uint8_t) 变量。Auint8_t只能保存 0 到 255 (= 2^8-1) 之间的值。因此，response(= 256) 的大小将导致溢出。这导致responseLength设置为 0（= 256 模 2^8）。因此，您输入的响应长度nfc.inDataExchange()太短而无法容纳任何响应。

所以使用

uint8_t response[255];
uint8_t responseLength = sizeof(response);

应该管用。

于 2014-03-25T07:18:01.217 回答
0

这可能是题外话，但我遵循您在此处发布的完全相同的代码，但我使用的是 Seeed Studio 的 NFC Shield V2。我认为这可能对其他人也有帮助。我发现一旦我从中删除了 selectApdu 数组中的最后一个字节：

uint8_t selectApdu[] = { 
      0x00, /* CLA */
      0xA4, /* INS */
      0x04, /* P1  */
      0x00, /* P2  */
      0x05, /* Length of AID  */
      0xF2, 0x22, 0x22, 0x22, 0x22,
      0x00  /* Le  */};

对此：

uint8_t selectApdu[] = { 
          0x00, /* CLA */
          0xA4, /* INS */
          0x04, /* P1  */
          0x00, /* P2  */
          0x05, /* Length of AID  */
          0xF2, 0x22, 0x22, 0x22, 0x22};

这最终让我的三星 Note 4 可以与 Arduino 和 Seeed Studio 库提供的示例 android_hce 进行通信。

于 2015-01-30T06:50:42.423 回答