0

假设以下代码声明：

itcl::class ObjectA {
    private variable m_ownedObject
    private variable m_someVariable

   constructor {} \
   {
        set m_ownedObject [ObjectA #auto]
   }

   protected method SetSomeVariable {newVal} {
       set m_someVariable $newVal
   }

   public method SomeMethod{} {
       $m_ownedObject SetSomeVariable 5
   }
}

这是我知道如何m_someVariable从SomeMethodm_ownedObject 内部修改的唯一方法。在其他语言中（比如 C/C++/C#/Java 等等），我很确定我可以这样说：

m_ownedObject.m_someVariable = 5

有没有办法在 tcl 中做这样的事情，还是我总是需要创建受保护的 getter 和 setter？希望这是相当清楚的。

4

3 回答 3

2

您不能直接在 itcl 中执行您要求的操作。但是，这是 Tcl，您可以解决这个问题，并直接从任何地方设置成员变量。我使用了一个辅助例程memv，你可以通过它传递一个实例和一个变量名，它会返回一个对该变量的“引用”。

这显然绕过了 Itcl 设置的私有/受保护机制，因此您违反了使用它们的抽象。是否要使用它是您的决定。我发现它对于调试非常宝贵，但不要在生产代码中使用。

示例用法是：

set [memv m_ownedObject m_someVariable] 5

的代码memv是：

proc memv {obj varname} {
  # have to look up the variable, which might be in a base class
  # so do 'info variable' to get that, and the full name is the 3rd element

  # next two lines handle pulling apart an array
  set aindex ""
  regexp -- {^(.+)\((.+)\)$} $varname ignore varname aindex

  set var [lindex [$obj info variable $varname] 2]

  if {$aindex == ""} {
    return [list @itcl $obj $var]
  } else {
    return [list @itcl $obj $var\($aindex\)]
  }
}

同样，我有一个名为的辅助例程memv，它允许您调用任何方法（包括私有方法和受保护方法）。用法类似

[memf m_ownedObject SetSomeVariable] 5

它的代码是：

proc memf {obj fcnname} {
  set f [$obj info function $fcnname]
  if {[llength $f] != 5} {
    error "expected '$obj info function $fcnname' to return something like 'private proc ::namespace::name args {...}' but got: $f"
  }
  set fullname [lindex [$obj info function $fcnname] 2]
  set namespace [namespace qualifiers $fullname]
  set function [namespace tail $fullname]
  return [itcl::code -namespace $namespace $obj $function]
}
于 2010-02-04T20:15:16.817 回答
2 
$m_ownedObject configure -m_someVariable 5
于 2011-06-07T14:24:35.217 回答
1

如果您将变量声明为私有，则意味着只能从类内部访问。这也适用于 C/C++/Java ......所以我不确定你在期待什么。

无论如何，Tcl 是一种动态语言，所以你可以做类似的事情。

  itcl::class tclass {
      foreach v {time distance} {
        method get$v {} [subst -nocommands { return [subst $$v] }]
        method set$v nuval [subst -nocommands { set $v \$nuval } ]
        protected variable $v "Var $v"
      }
  }

它将创建您需要的所有内容；getters）setters

你可以在这里找到更多信息：http ://wiki.tcl.tk/17667

于 2010-02-04T16:51:35.247 回答