2

我建立了一个谓词，它将罗马数字转换为阿拉伯数字。唯一的问题是谓词是有限的：如果我想一次转换超过 3 个阿拉伯数字，它就不再起作用了。

这就是谓词应该如何工作：

?- convert([v,i,i],Arabic).
Arabic = 7.

到目前为止我的解决方案：

tran([],0).
tran(i,1).
tran(v,5).
tran(x,10).

convert([],X) :- X is 0, !.
convert([T],X) :- tran(T,E), X is E,!.
convert([T|Ts],X) :- tran(T,E), tran(Ts,Es), X is E+Es,!.
convert([T,Ts,Tss],X) :- tran(T,E), tran(Ts,Es), tran(Tss,Ess), X is E+Es+Ess.

我知道为什么谓词不能使用超过 3 个数字，我也可以扩展转换谓词，但使用与上图相同的模式。

如何使转换谓词更“通用”（以便它可以独立于数字数量工作）？或者您有其他想法如何编写谓词？谢谢 ：）

4

3 回答 3

3

我没有对此进行太多测试，但我已经在几个数字上进行了尝试，它似乎有效。

该代码遵循“减法对规则”，例如，在https://projecteuler.net/about=roman_numerals

该代码使用“累加器”技术来传递信息，之前看到的数字总和是多少。初始调用只是将累加器设置为 0。

digit(i, 1).
digit(v, 5).
digit(x, 10).
digit(l, 50).
digit(c, 100).
digit(d, 500).
digit(m, 1000).

convert(Roman, Arabic) :-
    convert(Roman, 0, Arabic).

convert([], Acc, Acc).

convert([A], Acc, Arabic) :-
    digit(A, AVal),
    Arabic is Acc + AVal.

convert([A, B | Rest], Acc, Arabic) :-
    digit(A, AVal), digit(B, BVal),
    AVal < BVal,
    NewAcc is Acc + BVal - AVal,
    convert(Rest, NewAcc, Arabic).

convert([A, B | Rest], Acc, Arabic) :-
    digit(A, AVal), digit(B, BVal),
    AVal >= BVal,
    NewAcc is Acc + AVal,
    convert([B | Rest], NewAcc, Arabic).

一些测试：

convert([v, i, i], Arabic).
Arabic = 7 

?- convert([x, i, x], Arabic).
Arabic = 19 

?- convert([m, d, c, v, i], Arabic).
Arabic = 1606

使用约束编程可能可以编写一个convert以真正的 Prolog 精神双向工作的谓词，但我还没有尝试过这种方法。

于 2014-02-04T01:39:17.287 回答
3

如果您考虑罗马编号系统中离散“数字”的数量不仅仅是 I、X 和 V，这可能会有所帮助，即：

roman( "M"   , 1000 ) .
roman( "CM"  ,  900 ) .
roman( "D"   ,  500 ) .
roman( "CD"  ,  400 ) .
roman( "C"   ,  100 ) .
roman( "XC"  ,   90 ) .
roman( "L"   ,   50 ) .
roman( "XL"  ,   40 ) .
roman( "X"   ,   10 ) .
roman( "IX"  ,    9 ) .
roman( "V"   ,    5 ) .
roman( "IV"  ,    4 ) .
roman( "I"   ,    1 ) .

然后你可以写类似

roman_to_decimal( R , D ) :-
  roman_to_decimal( R , 0 , D )
  .

roman_to_decimal( [] , D , D ) :- .
roman_to_decimal( R  , T , D ) :-
  roman(P,V) ,
  append(P,S,R) ,
  ! ,
  T1 is T+V ,
  roman_to_decimal(S,T1,D)
  .

将其调用为

roman_to_decimal( "MCM" , D ) .

这确实有一些缺点：

  • 它不强制语法：罗马编号系统要求离散组件按值的降序从左到右排序。这没有考虑到这一点。

  • 它没有考虑到许多变化。999 应该表示为紧凑的IM还是更冗长的CMXCIX？

于 2014-02-04T01:52:01.217 回答
2

只是为了在混合中添加一个变体，这个版本使用了 Sergey 的答案中的方案（它也允许更多任意的减法序列），并允许像 Nicholas 的答案那样更易于阅读的输入。

numeral('I', 1).
numeral('V', 5).
numeral('X', 10).
numeral('L', 50).
numeral('C', 100).
numeral('D', 100).
numeral('M', 1000).

r2n(R, N) :-
    char_code(A, R),
    lower_upper(A, C),
    numeral(C, N).

trans(R, N) :-
    maplist(r2n, R, Rn),    % Pre-calculate a numeric list representation
    trans(Rn, 0, N).
trans([X,Y|T], Acc, N) :-
    X >= Y,
    Acc1 is Acc + X,
    trans([Y|T], Acc1, N).
trans([X,Y|T], Acc, N) :-
    X < Y,
    Acc1 is Acc - X,
    trans([Y|T], Acc1, N).
trans([X], Acc, N) :-
    N is Acc + X.
trans([], N, N).   % Optional rule: needed only if you want trans("", 0). to succeed

请注意，这些规则将允许任何有效的罗马数字，但也会对一些格式不正确的罗马数字进行处理并成功。因此，验证正确的罗马数字并不是一套规则。

样本输出：

| ?- trans("mmxiv", X).

X = 2014 ? ;

no
| ?- trans("CMXCIX", X).

X = 999 ? ;

no
| ?- trans("IM", X).

X = 999 ? ;

no
| ?- trans("IVX", X).   % Not a properly-formed Roman numeral

X = 4 ? ;   % Uh... ok... I guess

no
于 2014-02-04T13:28:29.850 回答