0

我正在创建一个批处理脚本来从系统上所有本地固定磁盘的所有目录（而不是单个文件）中提取权限。这是有效的；我能够创建一个列出所有本地固定 NTFS 分区的临时文件。我可以从该临时文件（通常是 C: 驱动器）中取出第一行，然后对它运行 dir 命令，然后对它运行 icacls/cacls 命令。我遇到的问题是它不会循环返回以针对临时文件中列出的任何其他驱动器运行 dir 命令和 icacls/cacls 命令。任何帮助，将不胜感激。这是我的脚本：

wmic logicaldisk get caption, drivetype, filesystem | find "3" | find "NTFS" | find /v "Caption" > "tmp_drives.txt"

setlocal enableDelayedExpansion
for /f "delims=:" %%A in (tmp_drives.txt) do (

    dir %%A:\ /ad /s /b >> "%%A_dir.txt"

    set drive=%%A

    if exist "%systemroot%\system32\icacls.exe" goto icacls

    for /f "tokens=* usebackq" %%J in ("!drive!_dir.txt") do cacls "%%J" | find /v   "GENERIC_READ" | find /v "GENERIC_EXECUTE" >> "!drive!_Permissions.txt" 
    goto end

    :icacls
    for /f "tokens=* usebackq" %%J in ("!drive!_dir.txt") do icacls "%%J" | find /i /v "Successfully" >> "!drive!_Permissions.txt"

    :end
)
setlocal disableDelayedExpansion
del tmp_drives.txt
pause
4

1 回答 1

0 
wmic logicaldisk get caption, drivetype, filesystem | find "3" | find "NTFS" | find /v "Caption" > "tmp_drives.txt"

setlocal enableDelayedExpansion
for /f "delims=:" %%A in (tmp_drives.txt) do (

 dir %%A:\ /ad /s /b >> "%%A_dir.txt"

 set drive=%%A
 if exist "%systemroot%\system32\icacls.exe" (
  for /f "tokens=* usebackq" %%J in ("!drive!_dir.txt") do icacls "%%J" | find /i /v "Successfully" >> "!drive!_Permissions.txt"
 ) else (
  for /f "tokens=* usebackq" %%J in ("!drive!_dir.txt") do cacls "%%J" | find /v   "GENERIC_READ" | find /v "GENERIC_EXECUTE" >> "!drive!_Permissions.txt" 
 )
)
setlocal disableDelayedExpansion
del tmp_drives.txt
pause

我确实不喜欢代码块中的标签。我相信在某些版本下，它们不起作用并终止该块。试试这个 - 它只是您原件的编辑版本，但没有标签。

于 2014-01-28T18:06:35.693 回答