11

我试图弄清楚如何使用 Mathematica 来求解其中一些变量和系数是向量的方程组。一个简单的例子是

A + Vt = Pt

我知道A、V和P的大小，我必须求解t和 P 的方向。（基本上，给定两条射线 A 和 B，我知道关于 A 的一切，但只知道 B 的原点和大小，找出 B 的方向必须与 A 相交。）

现在，我知道如何手动解决这类问题，但这很慢而且容易出错，所以我希望我可以使用 Mathematica 来加快速度并检查错误。但是，我看不出如何让 Mathematica 以符号方式求解涉及此类向量的方程。

我查看了 VectorAnalysis 包，但没有找到任何相关的内容；同时，线性代数包似乎只有线性系统的求解器（这不是，因为我不知道t或P，只是|P|）。

我尝试做简单的事情：将向量扩展为它们的组件（假装它们是 3D）并解决它们，就好像我试图将两个参数函数等同起来一样，

Solve[ 
      { Function[t, {Bx + Vx*t, By + Vy*t, Bz + Vz*t}][t] == 
          Function[t, {Px*t, Py*t, Pz*t}][t],
        Px^2 + Py^2 + Pz^2 == Q^2 } , 
      { t, Px, Py, Pz } 
     ]

但是吐出的“解决方案”是系数和拥塞的巨大混乱。它还迫使我扩展我提供给它的每个维度。

我想要的是一个很好的点积、叉积和规范方面的符号解决方案：

替代文字

但我看不出如何判断Solve某些系数是向量而不是标量。

这可能吗？Mathematica 可以给我关于向量的符号解吗？还是我应该坚持使用 No.2 Pencil 技术？

（为了清楚起见，我对顶部特定方程的解决方案不感兴趣——我在问我是否可以使用 Mathematica 来解决这样的计算几何问题，一般来说，我不必将所有内容都表示为{Ax, Ay, Az}， ETC。）

4

3 回答 3

9

使用 Mathematica 7.0.1.0

Clear[A, V, P];
A = {1, 2, 3};
V = {4, 5, 6};
P = {P1, P2, P3};
Solve[A + V t == P, P]

输出：

{{P1 -> 1 + 4 t, P2 -> 2 + 5 t, P3 -> 3 (1 + 2 t)}}

如果数组或矩阵很大，输入 P = {P1, P2, P3} 可能会很烦人。

Clear[A, V, PP, P];
A = {1, 2, 3};
V = {4, 5, 6};
PP = Array[P, 3];
Solve[A + V t == PP, PP]

输出：

{{P[1] -> 1 + 4 t, P[2] -> 2 + 5 t, P[3] -> 3 (1 + 2 t)}}

矩阵向量内积：

Clear[A, xx, bb];
A = {{1, 5}, {6, 7}};
xx = Array[x, 2];
bb = Array[b, 2];
Solve[A.xx == bb, xx]

输出：

{{x[1] -> 1/23 (-7 b[1] + 5 b[2]), x[2] -> 1/23 (6 b[1] - b[2])}}

矩阵乘法：

Clear[A, BB, d];
A = {{1, 5}, {6, 7}};
BB = Array[B, {2, 2}];
d = {{6, 7}, {8, 9}};
Solve[A.BB == d]

输出：

{{B[1, 1] -> -(2/23), B[2, 1] -> 28/23, B[1, 2] -> -(4/23), B[2, 2] -> 33/23}}

点积具有内置的中缀符号，仅使用句点作为点。

但是，我认为叉积不会。这就是你如何使用 Notation 包来制作一个。“X”将成为我们Cross的中缀形式。我建议处理 Notation、Symbolize 和 InfixNotation 教程中的示例。还可以使用 Notation Palette 帮助抽象出一些 Box 语法。

Clear[X]
Needs["Notation`"]
Notation[x_ X y_\[DoubleLongLeftRightArrow]Cross[x_, y_]]
Notation[NotationTemplateTag[
  RowBox[{x_,  , X,  , y_,  }]] \[DoubleLongLeftRightArrow] 
  NotationTemplateTag[RowBox[{ , 
RowBox[{Cross, [, 
RowBox[{x_, ,, y_}], ]}]}]]]
{a, b, c} X {x, y, z}

输出：

{-c y + b z, c x - a z, -b x + a y}

上面看起来很可怕，但是当使用 Notation Palette 时，它​​看起来像：

Clear[X]
Needs["Notation`"]
Notation[x_ X y_\[DoubleLongLeftRightArrow]Cross[x_, y_]]
{a, b, c} X {x, y, z}

我在过去版本的mathematica 中使用符号包遇到了一些怪癖，所以要小心。

于 2010-01-21T23:04:35.823 回答
5

我无论如何都没有为您提供通用解决方案（MathForum 可能是更好的方法），但我可以为您提供一些提示。首先是以更系统的方式将向量扩展为组件。例如，我将按如下方式求解您编写的方程式。

rawSol = With[{coords = {x, y, z}},
  Solve[
    Flatten[
     {A[#] + V[#] t == P[#] t & /@ coords,
     Total[P[#]^2 & /@ coords] == P^2}],
    Flatten[{t, P /@ coords}]]];

然后您可以rawSol更轻松地使用该变量。接下来，因为您以统一的方式引用向量组件（始终与 Mathematica 模式匹配v_[x|y|z]），您可以定义有助于简化它们的规则。在想出以下规则之前，我玩了一会儿：

vectorRules =
  {forms___ + vec_[x]^2 + vec_[y]^2 + vec_[z]^2 :> forms + vec^2,
   forms___ + c_. v1_[x]*v2_[x] + c_. v1_[y]*v2_[y] + c_. v1_[z]*v2_[z] :>
     forms + c v1\[CenterDot]v2};

这些规则将简化向量范数和点积的关系（交叉积对于读者来说可能是一个痛苦的练习）。编辑： rcollyer 指出您可以c在点积的规则中进行可选，因此您只需要规范和点积的两条规则。

有了这些规则，我立即能够将解决方案简化为t非常接近您的形式：

  In[3] := t /. rawSol //. vectorRules // Simplify // InputForm
  Out[3] = {(A \[CenterDot] V - Sqrt[A^2*(P^2 - V^2) + 
                                   (A \[CenterDot] V)^2])/(P^2 - V^2), 
            (A \[CenterDot] V + Sqrt[A^2*(P^2 - V^2) + 
                                   (A \[CenterDot] V)^2])/(P^2 - V^2)}

就像我说的，它不是以任何方式解决这类问题的完整方法，但如果你小心地将问题转换为从模式匹配和规则替换的角度易于处理的术语，你可以走得很远。

于 2010-01-21T16:12:23.517 回答
2

我对这个问题采取了一些不同的方法。我已经做出了一些返回此输出的定义： v展开示例 可以使用 指定已知为向量vec[_]的模式，默认情况下假定具有OverVector[]orOverHat[]包装器（带有向量或帽子的符号）的模式为向量。

这些定义是实验性的，应该这样对待，但它们似乎运作良好。我希望随着时间的推移增加这一点。

以下是定义。需要粘贴到 Mathematica Notebook 单元格并转换为 StandardForm 才能正确查看。

Unprotect[vExpand,vExpand$,Cross,Plus,Times,CenterDot];

(* vec[pat] determines if pat is a vector quantity.
vec[pat] can be used to define patterns that should be treated as vectors.
Default: Patterns are assumed to be scalar unless otherwise defined *)
vec[_]:=False;

(* Symbols with a vector hat, or vector operations on vectors are assumed to be vectors *)
vec[OverVector[_]]:=True;
vec[OverHat[_]]:=True;

vec[u_?vec+v_?vec]:=True;
vec[u_?vec-v_?vec]:=True;
vec[u_?vec\[Cross]v_?vec]:=True;
vec[u_?VectorQ]:=True;

(* Placeholder for matrix types *)
mat[a_]:=False;

(* Anything not defined as a vector or matrix is a scalar *)
scal[x_]:=!(vec[x]\[Or]mat[x]);
scal[x_?scal+y_?scal]:=True;scal[x_?scal y_?scal]:=True;

(* Scalars times vectors are vectors *)
vec[a_?scal u_?vec]:=True;
mat[a_?scal m_?mat]:=True;

vExpand$[u_?vec\[Cross](v_?vec+w_?vec)]:=vExpand$[u\[Cross]v]+vExpand$[u\[Cross]w];
vExpand$[(u_?vec+v_?vec)\[Cross]w_?vec]:=vExpand$[u\[Cross]w]+vExpand$[v\[Cross]w];
vExpand$[u_?vec\[CenterDot](v_?vec+w_?vec)]:=vExpand$[u\[CenterDot]v]+vExpand$[u\[CenterDot]w];
vExpand$[(u_?vec+v_?vec)\[CenterDot]w_?vec]:=vExpand$[u\[CenterDot]w]+vExpand$[v\[CenterDot]w];

vExpand$[s_?scal (u_?vec\[Cross]v_?vec)]:=Expand[s] vExpand$[u\[Cross]v];
vExpand$[s_?scal (u_?vec\[CenterDot]v_?vec)]:=Expand[s] vExpand$[u\[CenterDot]v];

vExpand$[Plus[x__]]:=vExpand$/@Plus[x];
vExpand$[s_?scal,Plus[x__]]:=Expand[s](vExpand$/@Plus[x]);
vExpand$[Times[x__]]:=vExpand$/@Times[x];

vExpand[e_]:=e//.e:>Expand[vExpand$[e]]

(* Some simplification rules *)
(u_?vec\[Cross]u_?vec):=\!\(\*OverscriptBox["0", "\[RightVector]"]\);
(u_?vec+\!\(\*OverscriptBox["0", "\[RightVector]"]\)):=u;
0v_?vec:=\!\(\*OverscriptBox["0", "\[RightVector]"]\);

\!\(\*OverscriptBox["0", "\[RightVector]"]\)\[CenterDot]v_?vec:=0;
v_?vec\[CenterDot]\!\(\*OverscriptBox["0", "\[RightVector]"]\):=0;

(a_?scal u_?vec)\[Cross]v_?vec :=a u\[Cross]v;u_?vec\[Cross](a_?scal v_?vec ):=a u\[Cross]v;
(a_?scal u_?vec)\[CenterDot]v_?vec :=a u\[CenterDot]v;
u_?vec\[CenterDot](a_?scal v_?vec) :=a u\[CenterDot]v;

(* Stealing behavior from Dot *)
Attributes[CenterDot]=Attributes[Dot];

Protect[vExpand,vExpand$,Cross,Plus,Times,CenterDot];
于 2011-09-07T10:12:45.463 回答