3

我想创建一个构建器来构建表达式，该表达式在每个步骤之后返回类似于延续的东西。

像这样的东西：

module TwoSteps = 
  let x = stepwise {
    let! y = "foo"
    printfn "got: %A" y
    let! z = y + "bar"
    printfn "got: %A" z
    return z
  }

  printfn "two steps"
  let a = x()
  printfn "something inbetween"
  let b = a()

'let a' 行返回包含稍后要评估的其余表达式的内容。

为每个步骤数使用单独的类型很简单，但当然不是特别有用：

type Stepwise() =
  let bnd (v: 'a) rest = fun () -> rest v
  let rtn v = fun () -> Some v
  member x.Bind(v, rest) = 
    bnd v rest
  member x.Return v = rtn v

let stepwise = Stepwise()

module TwoSteps = 
  let x = stepwise {
    let! y = "foo"
    printfn "got: %A" y
    let! z = y + "bar"
    printfn "got: %A" z
    return z
  }

  printfn "two steps"
  let a = x()
  printfn "something inbetween"
  let b = a()

module ThreeSteps = 
  let x = stepwise {
    let! y = "foo"
    printfn "got: %A" y
    let! z = y + "bar"
    printfn "got: %A" z
    let! z' = z + "third"
    printfn "got: %A" z'
    return z
  }

  printfn "three steps"
  let a = x()
  printfn "something inbetween"
  let b = a()
  printfn "something inbetween"
  let c = b()

结果就是我要找的：

two steps
got: "foo"
something inbetween
got: "foobar"
three steps
got: "foo"
something inbetween
got: "foobar"
something inbetween
got: "foobarthird"

但我无法弄清楚这种情况的一般情况是什么。

我想要的是能够将事件输入到这个工作流中，所以你可以编写如下内容：

let someHandler = Stepwise<someMergedEventStream>() {
  let! touchLocation = swallowEverythingUntilYouGetATouch()
  startSomeSound()
  let! nextTouchLocation = swallowEverythingUntilYouGetATouch()
  stopSomeSound()
}

并让事件触发工作流程中的下一步。（特别是，我想在 MonoTouch 中玩这种东西 - iPhone 上的 F#。传递 objc 选择器让我发疯。）

4

2 回答 2

2

您的实现的问题在于它为每次调用 Bind 返回“unit -> 'a”，因此对于不同数量的步骤，您将获得不同类型的结果（通常，这是 monad/computation 的可疑定义表达）。

正确的解决方案应该是使用其他类型，它可以表示具有任意步数的计算。您还需要区分两种类型的步骤 - 有些步骤只是评估计算的下一步，有些步骤返回结果（通过return关键字）。我将使用 type seq<option<'a>>。这是一个惰性序列，因此读取下一个元素将评估下一步的计算。该序列将包含None除最后一个值之外的值，最后一个值是Some(value)，表示使用 返回的结果return。

您实现中的另一个可疑之处是非标准类型的Bind成员。您的绑定将一个值作为第一个参数这一事实意味着您的代码看起来更简单（您可以编写let! a = 1）但是，您不能组成逐步计算。您可能希望能够编写：

let foo() = stepwise { 
  return 1; }
let bar() = stepwise { 
  let! a = foo()
  return a + 10 }

我上面描述的类型也将允许您编写它。一旦你有了类型，你只需要在实现中遵循和的类型签名，Bind你Return就会得到这个：

type Stepwise() = 
  member x.Bind(v:seq<option<_>>, rest:(_ -> seq<option<_>>)) = seq {
    let en = v.GetEnumerator()
    let nextVal() = 
      if en.MoveNext() then en.Current
      else failwith "Unexpected end!" 
    let last = ref (nextVal())
    while Option.isNone !last do
      // yield None for each step of the source 'stepwise' computation
      yield None
      last := next()
    // yield one more None for this step
    yield None      
    // run the rest of the computation
    yield! rest (Option.get !last) }
  member x.Return v = seq { 
    // single-step computation that yields the result
    yield Some(v) }

let stepwise = Stepwise() 
// simple function for creating single-step computations
let one v = stepwise.Return(v)

现在，让我们看看使用类型：

let oneStep = stepwise {
  // NOTE: we need to explicitly create single-step 
  // computations when we call the let! binder
  let! y = one( "foo" ) 
  printfn "got: %A" y 
  return y + "bar" } 

let threeSteps = stepwise { 
  let! x = oneStep // compose computations :-)
  printfn "got: %A" x 
  let! y = one( x + "third" )
  printfn "got: %A" y
  return "returning " + y }

如果您想逐步运行计算，您可以简单地迭代返回的序列，例如使用 F#for关键字。以下还打印步骤的索引：

for step, idx in Seq.zip threeSteps [ 1 .. 10] do
  printf "STEP %d: " idx
  match step with
  | None _ -> ()
  | Some(v) -> printfn "Final result: %s" v

希望这可以帮助！

PS：我发现这个问题很有趣！您介意我将答案添加到我的博客 ( http://tomasp.net/blog ) 的博客文章中吗？谢谢！

于 2010-01-08T20:01:27.973 回答
1

Monads 和计算构建器让我很困惑，但我已经适应了我在早期 SO 帖子中所做的一些事情。也许一些零碎的东西可以使用。

下面的代码包含一个动作队列和一个表单，其中 Click 事件侦听动作队列中可用的下一个动作。下面的代码是一个连续 4 个动作的示例。在 FSI 中执行它并开始单击表单。

open System.Collections.Generic
open System.Windows.Forms

type ActionQueue(actions: (System.EventArgs -> unit) list) =
    let actions = new Queue<System.EventArgs -> unit>(actions) //'a contains event properties
    with
        member hq.Add(action: System.EventArgs -> unit) = 
           actions.Enqueue(action)
        member hq.NextAction = 
            if actions.Count=0 
                then fun _ -> ()
                else actions.Dequeue()

//test code
let frm = new System.Windows.Forms.Form()

let myActions = [
    fun (e:System.EventArgs) -> printfn "You clicked with %A" (e :?> MouseEventArgs).Button
    fun _ -> printfn "Stop clicking me!!"
    fun _ -> printfn "I mean it!"
    fun _ -> printfn "I'll stop talking to you now."
    ]

let aq = new ActionQueue(myActions)

frm.Click.Add(fun e -> aq.NextAction e)

//frm.Click now executes the 4 actions in myActions in order and then does nothing on further clicks
frm.Show()

您可以单击表单 4 次，然后再单击不会发生任何事情。现在执行以下代码，表单将再响应两次：

let moreActions = [
    fun _ -> printfn "Ok, I'll talk to you again. Just don't click anymore, ever!"
    fun _ -> printfn "That's it. I'm done with you."
    ]

moreActions |> List.iter (aq.Add)
于 2010-01-08T11:10:16.070 回答