4

这对我来说太棒了哈哈，我几乎检查了 Google 搜索上的几乎每个页面，但我仍然不知道该怎么做。

我想在 VB 脚本中创建一个名为 data2 的多维数组。尝试我见过的示例，但出现“下标超出范围”错误

Dim data2()

sub grabdata
    SQL_query = "SELECT * FROM MSAccess_table"
    Set rsData = conn.Execute(SQL_query)
    Do Until rsData.EOF = True
        ReDim Preserve data2(UBound(data2) + 1)
        data2(UBound(data2)) = Array(rsData("id"),rsData("column_1"),rsData("column_2"),rsData("column_3"),rsData("column_4"))
    rsData.moveNext 
    Loop
end sub

基本上我正在尝试学习如何在 VB 脚本中创建一个多维数组并通过循环添加到它。在我的情况下可以使用哪些基本示例？

4

3 回答 3

9

(1) 将 ADO 结果集放入二维数组的最佳方法是使用.GetRows方法。然后你的问题就消失了。

(2) VBScript 中有两种数组。固定数组通过指定它们的 UBounds 来声明：

Dim aFix(2, 3)

它们无法调整大小。动态数组可以通过ReDim [Preserve]. 创建这样一个数组的最佳方法是

ReDim aDyn(2, 3)

如果您知道起始尺寸，或者

Dim aDyn : aDyn = Array()

如果你想从一个空的开始。要点 22 是：您只能对最后一个维度使用 Preserve。

(3) 你的

Dim data2()

是一个可憎的 - 一个没有大小的固定数组。遗憾的是，“编译器”太愚蠢了，无法捕捉到 VBScript 无法正确处理的野兽：

>> Dim data2()
>> WScript.Echo UBound(data2)
>>
Error Number:       9
Error Description:  Subscript out of range

该Dim a()语句的肮脏之处在于稍后ReDim会将适当的动态数组存储到该变量中这一事实：

>> Dim data2() ' <-- abomination
>> ReDim data2(1,1) ' <-- overwritten by a dynamic array
>> data2(0,0) = 0
>> ReDim Preserve data2(1,5) ' last dimension increased; 'old' data preserved
>> data2(1,5) = 1
>> WScript.Echo data2(0,0), data2(1,5)
>>
0 1

更新 wrt jmbpiano 的评论：

(1) 我提供了证据表明你不能得到一个用 () 变暗的变量的 UBound，所以我坚持我的说法，即这样的野兽是可憎的。只需看看问题（或这个问题），就会发现使用 () 会给您带来麻烦。

(2) 我说过你应该使用ReDim a(KnownUbound)“声明”一个已知大小的动态数组，但我没有提供证据证明这个成语的“选项显式”兼容性。所以 ：

Option Explicit
ReDim a(4711)
ReDim b(4,7,1,1)
a(0) = "qed"
b(0,0,0,0) = "qed"
WScript.Echo b(0,0,0,0)

输出：

cscript 19888987.vbs
qed
于 2013-11-10T11:46:51.577 回答
1

这可能是题外话，但是在看到您的确切代码之后，您为什么不使用内置的 ADO 函数：GetRows()？

    sub grabdata
        SQL_query = "SELECT * FROM MSAccess_table"
        Set rsData = conn.Execute(SQL_query)
        If Not rsData.EOF Then aData = rsData.GetRows()         
    end sub

这将返回所有列 # 作为第一个索引，并将行（数据）作为第二个索引。

因此，要遍历它，您将：

If IsArray(aData) Then
    For x = lBound(aData,2) to uBound(aData,2) 'loops through the rows
        Col1 = aData(0,x)
        Col2 = aData(1,x)
        Col3 = aData(2,x)
        Response.Write "Row #" & x+1 & "<br>"
        Response.Write "This is the data in Column1: " & Col1 & "<br>"
        Response.Write "This is the data in Column2: " & Col2 & "<br>"
        Response.Write "This is the data in Column3: " & Col3 & "<br>"
    Next
End If

*注意：默认情况下，行（和列）在数组中从 0 开始。

于 2014-01-15T18:44:54.470 回答
-3 
set rs = conn.execute(strQry)

arrRAY = rs.GetRows()

if isarray(arrRAY) then
  do stuff
end if
于 2015-09-15T19:18:34.207 回答