5

我是 Delphi 新手，动态创建新表单时遇到问题。我想使用我制作的 gui 中的元素属性创建新表单。这是我要动态创建的表单：

unit AddEmployeeF;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Buttons;

type
  TAddEmployee = class(TForm)
    GroupBox1: TGroupBox;
    AddName: TLabel;
    AddDept: TLabel;
    AddPhone: TLabel;
    AddExtension: TLabel;
    AddDetails: TLabel;
    Edit1: TEdit;
    Edit2: TEdit;
    Edit3: TEdit;
    Edit4: TEdit;
    Edit5: TEdit;
    BitBtn1: TBitBtn;
    BitBtn2: TBitBtn;
    procedure CancelButtonClick(Sender: TObject);
 private
    { Private declarations }
  public
    constructor CreateNew(AOwner: TComponent; Dummy: Integer = 0); override;
  end;
var
  AddEmployee: TAddEmployee;

implementation

{$R *.dfm}
      constructor TAddEmployee.CreateNew(AOwner: TComponent; Dummy: Integer = 0; Detail : String);
begin
  inherited Create(AOwner);
  AddDetails.Caption := Detail;
end;


procedure TAddEmployee.CancelButtonClick(Sender: TObject);
begin
    self.Close;
end;

end.

我不想在构造函数中再次创建所有 gui 元素，只是为了修改元素的一些属性，如标题，但保留 gui 定义中的位置和其他属性。这是可能的？以及如何从另一个表单创建表单，像这样？：

procedure TWelcome.SpeedButton1Click(Sender: TObject);
var
myForm :TAddEmployee;
begin
        myForm := TAddEmployee.CreateNew(AOwner, Dummy, Details);

     myForm.ShowModal;

end;
4

2 回答 2

8

您覆盖了错误的构造函数。构造TForm.CreateNew()函数绕过 DFM 流，因此不会在运行时创建所有设计时组件。更糟糕的是，您重写CreateNew()的构造函数正在调用内部调用的继承TForm.Create()构造函数，CreateNew()因此您将陷入无限循环，从而在运行时导致堆栈溢出错误。

要执行您的要求，请改写TForm.Create()构造函数，或定义一个在内部调用的全新构造函数TForm.Create()。完全不参与TForm.CreateNew()。

type
  TAddEmployee = class(TForm)
    ...
  public
    constructor Create(AOwner: TComponent); override; // optional
    constructor CreateWithDetail(AOwner: TComponent; Detail : String);
  end;

constructor TAddEmployee.Create(AOwner: TComponent);
begin
  CreateWithDetail(AOwner, 'Some Default Value Here');
end;

constructor TAddEmployee.CreateWithDetail(AOwner: TComponent; Detail : String);
begin
  inherited Create(AOwner);
  AddDetails.Caption := Detail;
end;


procedure TWelcome.SpeedButton1Click(Sender: TObject);
var
  myForm : TAddEmployee;
begin
  myForm := TAddEmployee.CreateWithDetail(AOwner, Details);
  myForm.ShowModal;
  myForm.Free;
end;
于 2013-11-03T07:54:29.587 回答
7

像这样声明你的构造函数：

constructor Create(AOwner: TComponent; const Detail: string); reintroduce;

像这样实现它：

constructor TAddEmployee.Create(AOwner: TComponent; const Detail: string);
begin
  inherited Create(AOwner);
  AddDetails.Caption := Detail;
end;

像这样称呼它：

myForm := TAddEmployee.Create(MainForm, Details);

我不确定您作为所有者想要传递什么。可能是主要形式，也可能是其他形式。

您还应该删除名为 AddEmployee 的全局变量，从而强制自己控制表单的实例化。

我选择将我的构造函数命名为 Create，因此隐藏了该名称的继承构造函数，以强制该类的使用者提供 Details 参数以创建该类的实例。

于 2013-11-03T07:50:42.483 回答