13

我正在尝试将今天的日期添加到 sheet2 中的 A 列。每次我的宏将我在 sheet1 B 列中的选择粘贴到 sheet2 中的新行时。

我的脚本可以添加新行并将我的选择粘贴到 sheet2 中，但我无法弄清楚我应该如何获取 sheet2 中新行的 A 列中的日期。这是我的宏中的脚本；

Sub move()  
        Dim i As Integer 
        Application.ScreenUpdating = False
        ActiveWorkbook.Sheets("Sheet1").Range("A1,A2,A3,A4,A5").Copy
       
        Sheets("Sheet2").Select
        i = 3
        While Range("B" & i).Value <> ""
            i = i + 1
        Wend
        Range("B" & i).Select
   
        Selection.PasteSpecial (xlValues), Transpose:=True
 
        Worksheets("Sheet1").Range("A1:A5").Clear
 
End Sub
4

2 回答 2

13

试试这个Date功能。它将以 MM/DD/YYYY 格式为您提供今天的日期。如果您正在寻找 MM-DD-YYYY 格式的今天日期，请尝试Date$. Now()还包括当前时间（您可能不需要）。这一切都取决于你需要什么。:)

于 2013-10-24T21:45:52.667 回答
4

这是一个将Now()值放在 A 列中 的示例。

Sub move()
    Dim i As Integer
    Dim sh1 As Worksheet
    Dim sh2 As Worksheet
    Dim nextRow As Long
    Dim copyRange As Range
    Dim destRange As Range

    Application.ScreenUpdating = False

        Set sh1 = ActiveWorkbook.Worksheets("Sheet1")
        Set sh2 = ActiveWorkbook.Worksheets("Sheet2")
        Set copyRange = sh1.Range("A1:A5")

        i = Application.WorksheetFunction.CountA(sh2.Range("B:B")) + 4

        Set destRange = sh2.Range("B" & i)

        destRange.Resize(1, copyRange.Rows.Count).Value = Application.Transpose(copyRange.Value)
        destRange.Offset(0, -1).Value = Format(Now(), "MMM-DD-YYYY")

        copyRange.Clear

    Application.ScreenUpdating = True

End Sub

有比使用While循环更好的方法来获取 B 列中的最后一行，这里有很多例子。有些比其他更好，但取决于您在做什么以及您的工作表结构是什么样的。我在这里使用了一个假设 B 列全为空，除了您要移动的行/记录。如果不是这种情况，或者B1:B3其中有一些值，则需要修改或使用其他方法。或者你可以只使用你的循环，但我会寻找替代品:)

于 2013-10-24T21:33:32.093 回答