2

我有数百个文件，其中也有数百个“应该”语句。

是否有任何自动化方法可以将这些文件更新为新语法？

我想要创建新文件和内联修改现有文件的选项。

4

2 回答 2

4

sed 是一个很好的工具。

下面将处理当前目录中的所有文件，并将它们写到目录中的新文件中_spec_seded。这目前处理了大约 99% 以上的更改，但可能仍会让您进行一些手动更改（数量取决于您的代码和编码风格）。

与 sed 脚本一样，您应该检查结果、运行差异并手动查看文件。理想情况下，您使用的是 git，这有助于使差异变得更加容易。

filenum=1
find . -type f -name '*_spec.rb' | while read file; do
  mkdir -p ../_spec_seded/"${file%/*}"
  echo "next file...$filenum...$file"
  let filenum+=1
  cp "$file" ../_spec_seded/"$file"

  sed -i '                           # Exclude:
/^ *describe .*do/! {                # -describe...do descriptions
  /^ *it .*do/! {                    # -it...do descriptions
    /^[[:blank:]]*\#/! {             # -comments
      /^ *def .*\.should.*/! {       # -inline methods
        /\.should/ {
          s/\.should/)\.to/                      # Change .should to .to
          s/\(\S\)/expect(\1/                    # Add expect( at start of line.
          /\.to\( \|_not \)>\=/ s/>\=/be >\=/    # Change operators for
          /\.to\( \|_not \)>[^=]/ s/>/be >/      # >, >=, <, <= and !=
          /\.to\( \|_not \)<\=/ s/<\=/be <\=/
          /\.to\( \|_not \)<[^=]/ s/</be </
          /\.to\( \|_not \)\!\=/ s/\!\=/be \!\=/
        }

        /\.to +==\( +\|$\)/ s/==/eq/
        /=\~/ {                                      # Change match operator
          s/=\~/match(/
          s/$/ )/
          s/\[ )$/\[/
        }

        s/[^}.to|end.to]\.to /).to /                 # Add paren
        /eq ({.*} )/ s/ ({/ ( {/                     # Add space
        /to\(_\|_not_\)receive/ s/_receive/ receive/ # receive
        /\.to eq \[.*\]/ {
          s/ eq \[/ match_array([/
          s/\]$/\])/
        }

        /expect.*(.*lambda.*{.*})/ {                 # Remove unneeded lambdas
          s/( *lambda *{/{/
          s/ })\.to / }\.to /
        }

        /expect *{ *.*(.*) *})\.to/ {                  # Fix extra end paren
          s/})\.to/}\.to/
        }
      }
    }
  }
}' ../_spec_seded/"$file"
done

请谨慎使用。目前，为了安全起见，该脚本_seded/首先创建新文件以供审查。该脚本放置在/spec目录中并从那里运行。如果您有数百个文件，这可以为您节省数小时或数天的工作！如果您使用它，我建议“第 2 步”手动将文件复制_spec_seded到spec自身并运行它们。我建议您不要只重命名整个目录。一方面，文件，例如spec_helper.rb当前未复制到_spec_seded.

11/18/2013 注意：我继续升级这个脚本。覆盖更多的边缘情况，并使匹配更具体，同时排除更多的边缘情况，例如注释行。

PS 可以看到应该审查的差异（从项目目录根目录）：

diff -r /spec /_spec_seded

git 也有很好的差异选项，但我喜欢在将文件添加到 git 之前查看。

于 2013-10-24T15:48:45.597 回答
4

迟来的更新，主要针对那些可能通过搜索引擎找到此页面的人。

为此，请使用 Yuji Nakayama 出色的Transpec宝石。我现在在不同的项目上使用它超过 10 次，没有问题。

从网站：

Transpec 让您可以立即将您的 RSpec 2 规格升级到 RSpec 3。它支持几乎所有 RSpec 3 更改的转换，并且由 RSpec 团队推荐。

此外，即使您暂时不打算将其升级到 RSpec 3，您也可以在您的 RSpec 2 项目中使用它。

于 2014-07-08T12:47:53.850 回答