0

我无法分离我的文件：

chr2    215672546   rs6435862   G   T   54.00   LowDP;sb DP=10;TI=NM_000465;GI=BARD1;FC=Silent   ...   ...

我想打印前七个字段，然后从第 8 个字段打印DP=10和GI=BARD1。DPin GIinfo 总是在第 8 个字段中。字段继续（...），因此第 8 个字段不是最后一个。

我知道如何提取第 8 个字段：

awk '{print $8}' PLZ-10_S2.vcf  | awk -F ";" '/DP/ {OFS="\t"} {print $1}'

当然如何提取前七个字段，但是如何将它们连接在一起呢？所有字段之间是tab.

4

2 回答 2

2

如果 DP= 和 GI= 在 $8 内始终处于相同位置：

$ awk 'BEGIN{FS=OFS="\t"} {split($8,a,/;/); $8=a[1]";"a[3]} 1' file
chr2    215672546       rs6435862       G       T       54.00   LowDP;sb       DP=10;GI=BARD1   ...     ...

如果不：

$ awk 'BEGIN{FS=OFS="\t"} {split($8,a,/;/); $8=""; for (i=1;i in a;i++) $8 = $8 (a[i] ~ /^(DP|GI)=/ ? ($8?";":"") a[i] : "")} 1' file
chr2    215672546       rs6435862       G       T       54.00   LowDP;sb       DP=10;GI=BARD1   ...     ...
于 2013-10-15T12:12:02.067 回答
1

一种方法是split()在八个字段中使用分号并遍历所有结果以检查其中哪些以DPor开头GI：

awk '
    BEGIN { FS = OFS = "\t" }

    { 
        split( $8, arr8, /;/ )
        $8 = "" 
        for ( i = 1; i <= length(arr8); i++ ) {
            if ( arr8[i] ~ /^(DP|GI)/ ) { 
                $8 = $8 arr8[i] ";" 
            }
        }
        $8 = substr( $8, 1, length($8) - 1 )
        print $0
    }
' infile

它产生：

chr2    215672546   rs6435862   G   T   54.00   LowDP;sb    DP=10;GI=BARD1  ... ...
于 2013-10-15T10:02:14.160 回答