xml - 用元素名称替换重复的属性值

Question

假设我有以下 XML：

<element1 title="title1">
<element2 title="title2">
<element3 title="title1">

这里的属性 titleelement1与 和重复element3。我想找到所有重复的元素，title并用元素名称替换title值。因此，上面的示例将是：

<element1 title="element1">
<element2 title="title2">
<element3 title="element3">

XSLT 1.0 怎么可能？

Answer 1

I. 这种转变：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match=
  "@title[. = ../preceding::*/@title
         or
          . = ../following::*/@title
          ]">
  <xsl:attribute name="title"><xsl:value-of select="name(..)"/></xsl:attribute>
 </xsl:template>
</xsl:stylesheet>

应用于以下 XML 文档时：

<t>
    <element1 title="title1"/>
    <element2 title="title2"/>
    <element3 title="title1"/>
</t>

产生想要的正确结果：

<t>
   <element1 title="element1"/>
   <element2 title="title2"/>
   <element3 title="element3"/>
</t>

---

二、使用键可能更有效的解决方案：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kTitleVyVal" match="@title" use="."/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match=
  "@title[key('kTitleVyVal', .)[2]]">
  <xsl:attribute name="title"><xsl:value-of select="name(..)"/></xsl:attribute>
 </xsl:template>
</xsl:stylesheet>