0

是否可以在 SPARQL 或 Jena 中计算两个语句之间的距离？例如，是否可以计算以下之间的距离：

immanuel_kant dbprop:birthPlace Germany
John_Lock     dbprop:birthPlace England
4

1 回答 1

1

很难准确地说出您要计算什么（因为我们还没有被告知），但听起来您可以在 SPARQL 中执行此操作。以下查询首先计算哲学家对的相似性度量并将其绑定到?initialSimilarity. 这只是他们名字长度的比例。这不是一个特别好的相似性度量，但您说您已经定义了其中的一些（评论中提到的 .60）。然后查询检索两位哲学家的出生地。如果它们相同，则将 0.05 添加到相似度度量中，或者如果它们不同，则减去 0.05，并且此值绑定到?finalSimilarity。（请注意，个人可能对birthPlace 属性有多个值，所以你'n × m次，其中n是一个人拥有的出生地数量，m是另一个人拥有的出生地数量。你可以在这里成对分组，然后取最终相似度的平均值，或者你可以做一些事情来解决多个陈述，例如，为每个陈述取样一个有代表性的出生地。）

select ?name1 ?name2 ?bp1 ?bp2 ?initialSimilarity ?finalSimilarity where { 
  dbpedia-owl:Philosopher ^a ?phil1, ?phil2 .
  ?phil1 rdfs:label ?name1 .
  ?phil2 rdfs:label ?name2 .
  filter( langMatches(lang(?name1),"en") && langMatches(lang(?name2),"en"))

  bind ( strlen(?name1) as ?len1 )
  bind ( strlen(?name2) as ?len2 )
  bind ( if(?len1 < ?len2, ?len1, ?len2) as ?minLen )
  bind ( if(?len1 < ?len2, ?len2, ?len1) as ?maxLen )
  bind ( ?minLen/xsd:double(?maxLen) as ?initialSimilarity )

  ?phil1 dbpedia-owl:birthPlace ?bp1 .
  ?phil2 dbpedia-owl:birthPlace ?bp2 .
  bind ( if( ?bp1 = ?bp2, ?initialSimilarity + .05, ?initialSimilarity - .05) as ?finalSimilarity )
}
limit 10

SPARQL 结果

根据评论中的说明，计算您的初始相似性指标并不难，您将其定义为共同类的数量与个人总共拥有的类的数量。这可以通过这样的查询来完成：

select ?philosopher1
       ?philosopher2
       (count(distinct ?commonType) as ?intersection)
       (count(distinct ?eitherType) as ?union)
       (count(distinct ?commonType)/xsd:double(count(distinct ?eitherType)) as ?similarity)
where {
  dbpedia-owl:Philosopher ^a ?philosopher1, ?philosopher2 .
  filter( ?philosopher1 != ?philosopher2 )
  ?commonType ^a ?philosopher1, ?philosopher2 .
  { ?eitherType ^a ?philosopher1 } UNION
  { ?eitherType ^a ?philosopher2 } 
}
group by ?philosopher1 ?philosopher2 
limit 3

SPARQL 结果

产生这样的结果：

philosopher1                                  philosopher2                                    intersection  union similarity
http://dbpedia.org/resource/Bawa_Muhaiyaddeen http://dbpedia.org/resource/Abdolkarim_Soroush  6             34    0.176471
http://dbpedia.org/resource/Eric_Voegelin     http://dbpedia.org/resource/Abdolkarim_Soroush  6             30    0.2
http://dbpedia.org/resource/Eric_Ormsby       http://dbpedia.org/resource/%C3%89mile_Meyerson 18            24    0.75

您需要做的就是使用第一个查询来额外选择哲学家的出生地，然后执行您用来计算相似度的任何公式以获得相似度修饰符，然后您可以修改相似度值。

于 2013-10-08T15:35:41.490 回答