0

好的，在来这里询问之前我已经尝试了所有方法，但这让我发疯了。

我正在创建一种用于在自定义 NoSQL 数据库中查询文档的简单语言。示例查询如下所示：

VALUE("price: " SUM($price) " Average: " AVG($price)).MATCH($price > 5 OR $price < 100 OR $cost > 30)

它介于 SQL 和 MONGODB 的聚合查询之间（VALUE 中的参数连接字符串和聚合，在匹配中有一个布尔匹配）。

问题是，当我解析这个时，我得到一行 1:69 无关的输入 ' ' 期望 COMPARATOR后跟一行 1:69 在输入 ' ' 处没有可行的替代方案。这与第 80-82 行和第 95-97 行相同。

如您所见，问题在于比较器（'<'、'>' 等）。我一直在寻找我的语法是否存在冲突或歧义，但没有任何运气（诚然，我最近才进入 ANTLR）。

这是我的语法：

// Define a grammar called Capsa
grammar Capsa;

eval : VARIABLE | function;

function : functionValue;

functionValue : 'VALUE(' (STRING ' ')* functionNumber (' '(STRING|functionNumber))* ')' (match)?;

match : '.MATCH(' booleanexpression ')';

functionNumber: FUNCTIONNUMBERTYPE'(' value ')';
FUNCTIONNUMBERTYPE: 'SUM'|'AVG'|'MAX'|'MIN'|'FIRST'|'LAST' ;

value
  : VARIABLE          #Var
  | REALNUMBER        #Literal
  | STRING            #Literal
  | calcexpression    #Calc
  | booleanValue      #Literal;

/*
** Boolean stuff
*/
AND : '&&' | ' AND ';
OR : '||' | ' OR ';
NOT : '!' | ' NOT ';

booleanexpression : '(' booleanexpression ')'   #BooleanParentExpression
  | booleanexpression AND booleanexpression     #AndExpression
  | booleanexpression OR booleanexpression      #OrExpression
  | NOT booleanexpression                       #NotExpression
  | (value COMPARATOR value)                    #Comparison
  | booleanValue                                #ComparisonLogic;

booleanValue
  : 'true'
  | 'false';
/*
** Comparators
*/
fragment GT : '>';
fragment GTE : '>=';
fragment LT : '<';
fragment LTE : '<=';
fragment EQ : '=';
fragment EX : ':' | '==';
COMPARATOR : GT | GTE | LT | LTE | EQ | EX;
/*
** End Comparators
*/

/*
** End Boolean stuff
*/

/*
** Calc
*/
calcexpression
  : '(' calcexpression ')'                    #CalcParentExpression
  | calcexpression ('*'|'/') calcexpression   #MultOrDiv
  | calcexpression ('+'|'-') calcexpression   #AddOrSub
  | VARIABLE                                  #CalcID
  | REALNUMBER                                #CalcNumber;

/*
** End Calc
*/

fragment ID : [a-zA-Z_][a-zA-Z0-9_]+ ;
VARIABLE : '$'ID;
STRING : '"' (ESC | ~["\\])* '"' ;
fragment CONSTANT : STRING | REALNUMBER;

fragment ESC : '\\' (["\\/bfnrt] | UNICODE) ;
fragment UNICODE : 'u' HEX HEX HEX HEX ;
fragment HEX : [0-9a-fA-F] ;
fragment INT : [0-9]+ ; // no leading zeros
fragment EXP : [Ee] [+\-]? INT ; // \- since - means "range" inside [...]

REALNUMBER
: '-'? INT '.' INT EXP? // 1.35, 1.35E-9, 0.3, -4.5
| '-'? INT EXP // 1e10 -3e4
| '-'? INT // -3, 45
;

WS : [ \t\r\n]+ -> skip ; // skip spaces, tabs, newlines

到目前为止，我发现的唯一解决方案是更改以下内容：

  | (value COMPARATOR value)                    #Comparison

为了：

  | (value ' '* COMPARATOR ' '* value)                    #Comparison

但看起来更像是一个黑客而不是我的解决方案......

我错过了什么？我很确定这将是一件非常愚蠢的事情......但我花了一整天的时间在这上面没有运气......

奖励曲目：

（这个不那么重要）我也试图在布尔查询中允许计算表达式（如 5+3 > 6 或 $variable+10 < 100），但在这种情况下，完全打破预期比较器（'> ', '<', ...)，当运算符 ('+', '-', ...) 存在时。

4

1 回答 1

1

您省略了空格，那么为什么要' '在语法规则中匹配functionValue？

删除此部分，您将获得完整的工作语法（在您给定的示例中），包括计算表达式的正确解析。

现在的规则是：

functionValue : 'VALUE(' (STRING)* functionNumber ((STRING|functionNumber))* ')' (match)?;

玩得开心 ANTLR4，它是一个非常好的工具。

PS：考虑拆分解析器语法和词法分析器语法，它将为您提供两个更好阅读的文件。

他们的标题将是

CapsaParser.g4

parser grammar CapsaParser;
options { tokenVocab = CapsaLexer; }

CapsaLexer.g4

lexer grammar CapsaLexer;
于 2013-10-07T13:27:46.273 回答