qt - QML - MouseArea/MouseEvent 问题

Question

以下代码生成一个白色矩形，其中包含一个红色矩形和一个灰色矩形。每个矩形都有一个关联的 MouseArea。当鼠标在其中单击时，灰色矩形变为蓝色。当鼠标光标进入其中时，红色矩形会打印一条控制台消息，并在发出释放信号时打印另一条消息。

我想：

1. 在灰色矩形内按住鼠标按钮（变为蓝色）
2. 将光标移到灰色/蓝色矩形之外，然后移到红色矩形内，而不释放按钮并捕获红色矩形的输入信号
3. 释放光标在红色矩形内的按钮并捕获红色矩形的释放信号。

是否可以？使用当前代码，只有在进入时没有按下 mopuse 按钮​​时才会发出红色矩形的输入信号，并且只有在该矩形内按下按钮时才会发出释放信号。显然，问题在于如果在那里按下按钮，灰色/蓝色矩形将控制鼠标事件。

这与我正在开发的应用程序中的场景类似，但经过了简化。

import QtQuick 2.0

Rectangle{
    color: "white"
    height: 210
    width: 500

    MouseArea{
      id: mainMa
      anchors.fill: parent
      hoverEnabled: true
      onReleased:{console.log("white-released")}
   }

   Column{
       spacing: 10
       Rectangle{
           color: "red"
           height: 100
           width: 500
          MouseArea{
             anchors.fill: parent
             hoverEnabled: true
             propagateComposedEvents: true
             onEntered:{console.log("red-enter")}
             onReleased:{console.log("red-released")}
          }
       }

       Rectangle{
           color: "#666666"
           height: 100
           width: 500
           MouseArea{
               id: ma
               anchors.fill: parent
               hoverEnabled: true
               onPressed: {parent.color = "blue"; console.log("grey pressed")}
               onReleased: {parent.color = "#666666"; console.log("grey released")}
           }
       }
   }

}

Answer 1

我想你想要拖放操作。为此，在红色矩形中添加 DropArea 并在灰色矩形中主动拖动

类似的东西（最少的代码）：

Rectangle {
    Column {
        Rectangle {
            id: redRect
            DropArea {
                anchors.fill: parent
                onEntered: { console.log("red-enter") }
                onDropped: { console.log("red-released") }
            }
        }
        Rectangle {
            id: greyRect
            Drag.active: mousearea.drag.active
            Drag.hotSpot.x: mousearea.mouseX
            Drag.hotSpot.y: mousearea.mouseY
            MouseArea {
                id: mousearea
                anchors.fill: parent
                onReleased: parent.Drag.drop()
                drag.target: parent
            }
        }
    }
}

如果不想移动灰色矩形，可以添加不可见的可拖动项：

    MouseArea {
    id: mousearea
    anchors.fill: parent
    onReleased: dargItem.Drag.drop()
    drag.target: dargItem
    Item {
        id: dargItem
        x: mousearea.mouseX
        y: mousearea.mouseY
        width: 1; height: 1
        Drag.active: mousearea.drag.active
        Drag.hotSpot.x: 1
        Drag.hotSpot.y: 1
    }                    
}