我想使用 gnuplot 在椭球边界内创建和绘制一组随机点。是否可以直接在 gnuplot 中执行此操作，还是需要在外部程序中生成随机数据点？
最终我想制作一个类似于这个椭圆形的椭圆形。
问问题
1929 次
2 回答
4
根据@Bernhard 的回答，以下是仅使用 gnuplot 的方法。要重用随机数，您可以将两个rand调用和对变量的赋值放在using语句的第一个参数中，用逗号分隔。这些using语句从左到右进行评估，因此您可以在所有以下using参数中访问这些变量。
为了证明这一点，请参见以下示例：
set samples 1000
plot '+' using (x=rand(0), y=rand(0), x):(y)
将此应用于椭圆体，这给出了脚本：
a=3
b=2
phi=30*pi/180
max(x,y) = (x > y ? x : y)
set xrange[-max(a,b):max(a,b)]
set yrange[-max(a,b):max(a,b)]
set offset 0.1,0.1,0.1,0.1
set samples 2000
ex(x, y) = a*(2*x-1)
ey(x, y) = b*(sqrt(1-((2*x-1))**2))*(2*y-1)
unset key
plot '+' using (x=rand(0), y=rand(0), ex(x,y)*cos(phi)-ey(x,y)*sin(phi)):\
(ey(x,y)*cos(phi)+ex(x,y)*sin(phi)) pt 7 ps 0.5
结果：
但是，这会导致点的分布明显不均（请参阅椭圆末端的聚集，请参阅@andyras 的评论）。为避免这种情况，您可以通过以下方法将均匀分布的随机点过滤到椭圆体内：
a=3
b=2
set angles degree
phi=30
max(x,y) = (x > y ? x : y)
set xrange[-max(a,b):max(a,b)]
set yrange[-max(a,b):max(a,b)]
set offset 0.1,0.1,0.1,0.1
set samples 2000
set size ratio 1
check(x, y) = (((x/a)**2 + (y/b)**2) <= 1)
unset key
plot '+' using (x=2*a*(rand(0)-0.5), y=2*b*(rand(0)-0.5), \
check(x,y) ? x*cos(phi)-y*sin(phi) : 1/0):\
(x*sin(phi)+y*cos(phi)) pt 7 ps 0.5
这给出了更好的结果：
将其扩展到三个维度：
a=3
b=1
c=1
set angles degree
phi=30
mx(x,y) = (x > y ? x : y)
max(x,y,z) = mx(mx(x,y), mx(x,z))
set xrange[-max(a,b,c):max(a,b,c)]
set yrange[-max(a,b,c):max(a,b,c)]
set zrange[-max(a,b,c):max(a,b,c)]
set offset 0.1,0.1,0.1,0.1
set samples 2000
set size ratio 1
set ticslevel 0
set view 60, 330
check(x, y, z) = (((x/a)**2 + (y/b)**2 + (z/c)**2) <= 1)
unset key
splot '+' using (x = 2*a*(rand(0)-0.5), \
y = 2*b*(rand(0)-0.5), \
z=2*c*(rand(0)-0.5), \
check(x,y,z) ? x*cos(phi)-y*sin(phi) : 1/0):\
(x*sin(phi)+y*cos(phi)):(z) pt 7 ps 0.5
结果：
于 2013-09-11T07:11:08.203 回答
2
我没有找到rand(0)在您展示的参数绘图示例中重用 的方法，但是通过对命令行工具的内部调用，您可以通过一些修改来做到这一点：
unset key
a=3
b=2
set xrange [-a:a]
set yrange [-b:b]
set style function dots
plot "<seq 1000 | awk '{print rand(), rand()}'" using (a*(2*$1-1)):(b*(sqrt(1-((2*$1-1))**2))*(2*$2-1))
将其转换为 3D 留给读者作为练习（继续这些表达式）
于 2013-09-11T06:14:58.283 回答