3

我试图在 DBGrid 中用 Yes/No 替换 True/False。下面的代码几乎可以工作：

procedure TDatamodule1.DBGridDrawColumnCell(Sender: TObject;
  const Rect: TRect; DataCol: Integer; Column: TColumn; State: TGridDrawState);

  var
    sText : String;

begin
  if (UpperCase(Column.Field.FieldName) = UpperCase('Approved')) or
     (UpperCase(Column.Field.FieldName) = UpperCase('Obsolete')) then
    begin
      if Column.Field.Value = True then
        sText := 'Yes'
      Else
        If Column.Field.Value = False Then
          sText := 'No'
        Else
          sText := '';
      (Sender as TDBGrid).Canvas.FillRect(Rect);
      (Sender as TDBGrid).Canvas.TextRect(Rect, Rect.Left+3, Rect.Top+2, sText);
    end;
end;

这似乎有效，直到我开始使用键盘光标键在网格中移动。具有焦点的单元格始终将 True 和 Yes 或 False 和 No 绘制在彼此之上。如何防止在具有焦点的单元格上绘制默认的 True/False 标签？网格的所有其他单元格都是完美的。

编辑：我没有提到网格设置为只读，我注意到问题出在选中和集中。提前致谢。

4

4 回答 4

11

一个简单的解决方案是设置您的布尔字段DisplayValues：

MyField.DisplayValues := 'Yes;No';
于 2013-09-10T09:35:48.743 回答
4

实现此目的的一种方法是为这些字段设置 OnGetText 事件处理程序。如果您有静态字段，您可以在设计时设置它们。使用动态字段，您可以在 FormCreate 事件中这样做。

procedure TMyForm.MyFieldGetText(Sender: TField; var Text: string; DisplayText: Boolean);
begin
  if Sender.AsBoolean then
    Text := 'Yes'
  else
    Text := 'No';
end;
于 2013-09-10T06:52:38.160 回答
0

我会说你在错误的抽象级别上工作。使用两个计算列（下例中的 AFlag 和 OFlag）并为您的客户端数据集定义一个 OnCalcFields 事件。以下代码附加到名为“qCpap”的数据集。

procedure TView.qCpapCalcFields(DataSet: TDataSet);
begin
 if qCpapApproved.AsBoolean 
  then qCpapAFlag.AsString:= 'Yes'
  else qCpapAFlag.AsString:= 'No';

 if qCpapObsolete.AsBoolean 
  then qCpapOFlag.AsString:= 'Yes'
  else qCpapOFlag.AsString:= 'No';
end;

顺便说一句，在字符串常量上使用“大写”函数是没有意义的：您也可以自己将字符串写成大写。

于 2013-09-10T03:00:44.913 回答
0

我通过大量试验和错误解决了我的问题。首先，在 DBGrid 组件中，我将 dgEditing 设置为 false，因为它是不必要的（我的网格是只读的）。这可以防止用户使单元格进入聚焦模式。其次，我将 DefaultDrawing 设置为 False。我更新了我的 DBGridDrawColumnCell 过程如下：

procedure TDatamodule1.DBGridDrawColumnCell(Sender: TObject;
  const Rect: TRect; DataCol: Integer; Column: TColumn; State: TGridDrawState);

  var
    sText : String;

begin
  if gdselected in state then { set proper colors if cell is selected }
    Begin
      (Sender as TDBGrid).Canvas.Font.Color := 
        TStyleManager.ActiveStyle.GetSystemColor(clwindowtext);
      (Sender as TDBGrid).Canvas.Brush.Color := 
        TStyleManager.ActiveStyle.GetSystemColor(clhighlight);
    End;

  if (UpperCase(Column.Field.FieldName) = 'APPROVED') or
     (UpperCase(Column.Field.FieldName) = 'OBSOLETE')) then
    begin
      if Column.Field.Value = True then
        sText := 'Yes'
      Else
        If Column.Field.Value = False Then
          sText := 'No'
        Else
          sText := '';
      (Sender as TDBGrid).Canvas.FillRect(Rect);
      (Sender as TDBGrid).Canvas.TextRect(Rect, Rect.Left+3, Rect.Top+2, sText);
    end
  Else
    Begin { I added this to draw all other columns as defaultdrawing is off }
      (Sender as TDBGrid).defaultdrawcolumncell(Rect, DataCol, Column, State);
    End;
end;
于 2013-09-10T05:12:47.703 回答