1

我正在学习 xslt group-by。我有一个示例 xml 如下

<?xml version="1.0" encoding="UTF-8"?>
<h1>
    <a1>abcd</a1>
    <a2>efgh</a2>
    <h2>
        <b1>IV-3</b1>
        <b2>20.00</b2>
        <h3>
            <c1>VCH</c1>
            <c2>1001</c2>
            <c3>100.00</c3>
        </h3>
    </h2>
    <h2>
        <b1>IV-3</b1>
        <b2>50.00</b2>      
    </h2>   
    <h2>
        <b1>IV-3</b1>
        <b2>10.00</b2>
        <h3>
            <c1>VCH</c1>
            <c2>1001</c2>
            <c3>300.00</c3>
        </h3>
    </h2>
    <h2>
        <b1>IV-3</b1>
        <b2>30.00</b2>      
    </h2>
</h1>

我需要先对 b1 值进行分组并总结 b2 值，如果存在 h3 节点，则需要对 c2 进行分组并总结该组的 c3 值。我的 xslt 如下。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:template match="h1">
        <t1>
            <d1>
                <xsl:value-of select="a1"/>
            </d1>
            <d2>
                <xsl:value-of select="a2"/>
            </d2>
            <xsl:for-each-group select="h2" group-by="b1">
                <xsl:if test="current-group()/count(h3) > 0 ">
                    <xsl:for-each-group select="current-group()/h3" group-by="c2">
                        <t2>
                            <e1>
                                <xsl:value-of select="../b1"/>
                            </e1>
                            <e2>
                                <xsl:value-of select="format-number(sum(current-group()/../b2),'#.00')"/>
                            </e2>
                            <e3>
                            <xsl:value-of select="format-number(sum(current-group()/c3),'#.00')"/>
                            </e3>
                        </t2>
                    </xsl:for-each-group>
                </xsl:if>
                <xsl:if test="current-group()/count(h3) = 0 ">                  
                        <t2>
                            <e1>
                                <xsl:value-of select="b1"/>
                            </e1>
                            <e2>
                                <xsl:value-of select="format-number(sum(current-group()/b2),'#.00')"/>
                            </e2>
                            <e3>
                            <xsl:value-of select="11111"/>
                            </e3>
                        </t2>
                </xsl:if>
            </xsl:for-each-group>
        </t1>
    </xsl:template>
</xsl:stylesheet>

如果 h3 不存在，我为 e2 获得的聚合值不正确。预期的结果是

<?xml version="1.0" encoding="UTF-8"?>
<t1 xmlns:fn="http://www.w3.org/2005/xpath-functions" xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <d1>abcd</d1>
    <d2>efgh</d2>
    <t2>
        <e1>IV-3</e1>
        <e2>30.00</e2>
        <e3>400.00</e3>
    </t2>
    <t2>
        <e1>IV-3</e1>
        <e2>80.00</e2>
        <e3>11111</e3>
    </t2>
</t1>

谢谢您的帮助！

4

1 回答 1

0

您想一次对两个值进行分组，因此您必须更改group-by选择器。

从

<xsl:for-each-group select="h2" group-by="b1">

到

<xsl:for-each-group select="h2" group-by="concat(b1, '|', boolean(h3))">

除此之外，您的代码有效。

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions">
  <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" />
  <xsl:template match="h1">
    <t1>
      <d1>
        <xsl:value-of select="a1" />
      </d1>
      <d2>
        <xsl:value-of select="a2" />
      </d2>
      <xsl:for-each-group select="h2" group-by="concat(b1, '|', boolean(h3))">
        <xsl:if test="current-group()/h3">
          <xsl:for-each-group select="current-group()/h3" group-by="c2">
            <t2>
              <e1>
                <xsl:value-of select="../b1" />
              </e1>
              <e2>
                <xsl:value-of select="format-number(sum(current-group()/../b2), '#.00')" />
              </e2>
              <e3>
                <xsl:value-of select="format-number(sum(current-group()/c3), '#.00')" />
              </e3>
            </t2>
          </xsl:for-each-group>
        </xsl:if>
        <xsl:if test="not(current-group()/h3)">
          <t2>
            <e1>
              <xsl:value-of select="b1" />
            </e1>
            <e2>
              <xsl:value-of select="format-number(sum(current-group()/b2), '#.00')" />
            </e2>
            <e3>
              <xsl:value-of select="11111" />
            </e3>
          </t2>
        </xsl:if>
      </xsl:for-each-group>
    </t1>
  </xsl:template>
</xsl:stylesheet>

这个样式表产生想要的输出

<t1 xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions">
   <d1>abcd</d1>
   <d2>efgh</d2>
   <t2>
      <e1>IV-3</e1>
      <e2>30.00</e2>
      <e3>400.00</e3>
   </t2>
   <t2>
      <e1>IV-3</e1>
      <e2>80.00</e2>
      <e3>11111</e3>
   </t2>
</t1>

笔记

  • boolean(h3)发出字符串'true'或'false'取决于<h3>元素的存在
  • 以同样的方式，您的<xsl:if>测试可以分别简化为current-group()/h3和not(current-group()/h3)（空节点集计算为false）
  • 您应该exclude-result-prefixes="xs fn"声明从输出文档中删除不必要的命名空间声明。
于 2013-09-09T20:35:53.220 回答