1

我有这样的文件：

<?xml version="1.0" encoding="UTF-8"?>
<document>
    <data attribute1="12" attribute2="1" attribute3="1">Director</data>
    <data attribute1="12" attribute2="1" attribute3="5">James</data>
    <data attribute1="12" attribute2="1" attribute3="8">Male</data>
    <data attribute1="12" attribute2="1" attribute3="9">10-Dec-1965</data>
    <data attribute1="12" attribute2="2" attribute3="18">James@gmail.com</data>
    <data attribute1="12" attribute2="2" attribute3="1">Chief Account</data>
    <data attribute1="12" attribute2="2" attribute3="5">Anna</data>
    <data attribute1="12" attribute2="2" attribute3="8">Female</data>
    <data attribute1="12" attribute2="1" attribute3="9">5-Aug-1980</data>
    <data attribute1="12" attribute2="2" attribute3="18">Anna@gmail.com</data>
</document>

我想把它改成这样：

<Person>
    <Title>Director</Title>
    <FullName>James</FullName>
    <Gender>Male</Gender>
    <DateOfBirth>10-Dec-1965</DateOfBirth>
    <EmailAddress>James@gmail.com</EmailAddress>
</Person>
<Person>
    <Title>Chief Account</Title>
    <FullName>Anna</FullName>
    <Gender>Female</Gender>
    <DateOfBirth>5-Aug-1980</DateOfBirth>
    <EmailAddress>Anna@gmail.com</EmailAddress>
</Person>

我正在使用这个 xslt：

<xsl:for-each select="document/data[@attribute1=12]">
    <Person>
        <xsl:choose>
            <xsl:when test="boolean(./@attribute3 = '1')">
                <Title>
                    <xsl:value-of select="./."/>
                </Title>
            </xsl:when>
            <xsl:when test="boolean(./@attribute3 = '5')">
                <FullName>
                    <xsl:value-of select="./."/>
                </FullName>
            </xsl:when>
            <xsl:when test="boolean(./@attribute3 = '8')">
                <Gender>
                    <xsl:value-of select="./."/>
                </Gender>
            </xsl:when>
            <xsl:when test="boolean(./@attribute3 = '9')">
                <DateOfBirth>
                    <xsl:value-of select="./."/>
                </DateOfBirth>
            </xsl:when>
            <xsl:when test="boolean(./@attribute3 = '18')">
                <EmailAddress>
                    <xsl:value-of select="./."/>
                </EmailAddress>
            </xsl:when>
        </xsl:choose>
    </Person>
</xsl:for-each>

问题是我得到以下输出，其中<Person>标记重复。

<Person>
    <Title>Director</Title>
</Person>    
<Person>    
    <FullName>James</FullName>
</Person>    
<Person>  
    <Gender>Male</Gender>
</Person>
<Person>    
    <DateOfBirth>10-Dec-1965</DateOfBirth>
</Person>    
<Person>    
    <EmailAddress>James@gmail.com</EmailAddress>
</Person>
<Person>
    <Title>Chief Account</Title>
</Person>
<Person>
    <FullName>Anna</FullName>
</Person>
<Person>
    <Gender>Female</Gender>
</Person>
<Person>
    <DateOfBirth>5-Aug-1980</DateOfBirth>
</Person>
<Person>
    <EmailAddress>Anna@gmail.com</EmailAddress>
</Person>

谁能帮我解决这个问题？谢谢！

4

2 回答 2

0

这是我基于元素位置的建议：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="xml" indent="yes"/>

<xsl:param name="size" select="5"/>

<xsl:template match="document">
  <Persons>
    <xsl:apply-templates select="data[position() mod $size = 1]" mode="group"/>
  </Persons>
</xsl:template>

<xsl:template match="data" mode="group">
  <Person>
    <xsl:apply-templates select=". | following-sibling::data[position() &lt; $size]"/>
  </Person>
</xsl:template>

<xsl:template match="data[@attribute3 = '1']">
  <Title>
    <xsl:value-of select="."/>
  </Title>
</xsl:template>

<xsl:template match="data[@attribute3 = '5']">
  <FullName>
    <xsl:value-of select="."/>
  </FullName>
</xsl:template>

<xsl:template match="data[@attribute3 = '8']">
  <Gender>
    <xsl:value-of select="."/>
  </Gender>
</xsl:template>

<xsl:template match="data[@attribute3 = '9']">
  <DateOfBirth>
    <xsl:value-of select="."/>
  </DateOfBirth>
</xsl:template>

<xsl:template match="data[@attribute3 = '18']">
  <EmailAddress>
    <xsl:value-of select="."/>
  </EmailAddress>
</xsl:template>

</xsl:stylesheet>
于 2013-08-24T11:10:33.833 回答
0

看起来您希望为每个属性3 值为 1 的数据元素创建一个新的Person元素。不要像当前那样遍历所有数据元素，只需选择具有相关属性的元素

<xsl:apply-templates select="data[@attribute3='1']"/>

然后，您将拥有一个模板来仅为这些数据元素输出Person元素。

<xsl:template match="data[@attribute3='1']">
   <Person>
      <Title><xsl:value-of select="." /></Title>
      <!-- Select other elements here -->
   </Person>
</xsl:template>

现在，要获取其他元素，实现此目的的另一种方法是使用密钥。实际上，您将按属性3 值为“1”的第一个最前面的数据元素对数据元素进行分组。

<xsl:key name="data" 
         match="data[@attribute3 != '1']" 
         use="generate-id(preceding-sibling::data[@attribute3 = '1'][1])" />

然后，要选择其他元素，您可以使用此键，使用当前数据元素的唯一 ID 作为查找。

<xsl:apply-templates select="key('data', generate-id())" />

这只会选择构成该特定人员元素的数据元素。然后，您将拥有模板来匹配每个可能的属性值的其他数据元素：

试试这个 XSLT：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>

   <xsl:key name="data" match="data[@attribute3 != '1']" use="generate-id(preceding-sibling::data[@attribute3 = '1'][1])" />

   <xsl:template match="document">
         <xsl:apply-templates select="data[@attribute3='1']"/>
   </xsl:template>

   <xsl:template match="data[@attribute3='1']">
      <Person>
         <Title><xsl:value-of select="." /></Title>
         <xsl:apply-templates select="key('data', generate-id())" />
      </Person>
   </xsl:template>

   <xsl:template match="data[@attribute3='5']">
      <FullName><xsl:value-of select="." /></FullName>
   </xsl:template>

    <xsl:template match="data[@attribute3='8']">
      <Gender><xsl:value-of select="." /></Gender>
   </xsl:template>

    <xsl:template match="data[@attribute3='9']">
      <DateOfBirth><xsl:value-of select="." /></DateOfBirth>
   </xsl:template>

    <xsl:template match="data[@attribute3='18']">
      <EmailAddress><xsl:value-of select="." /></EmailAddress>
   </xsl:template>
</xsl:stylesheet>
于 2013-08-24T11:24:05.860 回答