3

我正在尝试使用一个非常强大的技巧来保存我输入的每个命令：

function zshaddhistory() {
    COMMAND_STR=${1%%$'\n'}
    [[ ( -z $COMMAND_STR ) || ( $COMMAND_STR =~ hist(ory)? ) || \
        ( $COMMAND_STR =~ ^l(s\|l\|a)?$ ) || \
        ( $COMMAND_STR =~ ^(d\|gd\|git\ diff\|glp\|gg)$ ) \
    ]] && return 1
    # do not do anything on common commands

    # do the needful
    echo "$PWD; $COMMAND_STR; $TTY@$HOST@$(date +%s.%N)" >> ~/.zsh_enhanced_history

    # rest is supposedly "default" zshaddhistory() (except it ain't)
    print -Sr ${COMMAND_STR}
    fc -p
}

让它正常工作是相当困难的（例如，使用print -S它不会搞砸!$等），但它现在主要对我有用。

但是，我注意到现在保存的内容存在一些细微的不一致，因为我正在构建一个 Python 脚本，该脚本将保存的命令漂亮地打印在彩色列中。

为了显示：

% echo "\\"
\

现在~/.zsh_enhanced_history现在包含：

/home/slu/util; echo "\"; /dev/pts/20@1376064693.136746657

因此，它将echo "\\"（产生输出\）保存为echo "\"（这不是一个格式正确的命令）。

同样，该命令echo "\n"使用文字换行符保存，因此它将占用历史文件中的两行。事实上，正是这种行为导致我最初找到它，因为我的 python 正则表达式会为一个命令产生与该命令中包含换行符一样多的失败解析。

我尝试更改它，以便保存printf "%q" "$COMMAND_STR"as的输出$COMMAND_STR，这似乎确实解决了换行符，甚至可能是反斜杠，但它使它转义了空格和双引号，所以它也是错误的。

常规~/.zsh_history文件不受此问题的影响，它包含与键入的命令完全相同的命令。

所以在我的某个地方，我zshaddhistory没有做正确的转换。也许我需要防止发生额外的 shell-string-eval 。

需要 zsh 专家的帮助！！

4

2 回答 2

0

zsh 邮件列表中的这个示例使用print. 将它与您的函数结合起来可以得到：

zshaddhistory () {
    # Print to the default history file with the newline stripped. 
    print -sr -- "${1%%$'\n'}"

    # Ignore common commands. 
    COMMAND_STR=${1%%$'\n'}
    [[ ( -z $COMMAND_STR ) || ( $COMMAND_STR =~ hist(ory)? ) || \
        ( $COMMAND_STR =~ ^l(s\|l\|a)?$ ) || \
        ( $COMMAND_STR =~ ^(d\|gd\|git\ diff\|glp\|gg)$ ) \
        ]] && return 1


    # Switch history contexts
    fc -p ~/.zsh_history_detail
    # Push the current line into the current history context with newline stripped and user / time appended. 
    print -sr -- "${1%%$'\n'} ### ${PWD} $(date '+%Y-%m-%d %R')"
    return 1
}

这似乎做你想做的事。我已经使用echo "\\"and进行了测试echo "\n"：

charizard% cat ~/.zsh_history_detail                               
cat: /Users/simont/.zsh_history_detail: No such file or directory
charizard% echo "\\"                                               
\
charizard% cat ~/.zsh_history_detail                               
: 1376117319:0;echo "\\" ### /Users/simont 2013-08-10 16:18
charizard% cat "\n"      # This was an oopsie                      
cat: \n: No such file or directory
charizard% echo "\n"                                               


charizard% echo "\\"                                               
\
charizard% cat ~/.zsh_history_detail                               
: 1376117319:0;echo "\\" ### /Users/simont 2013-08-10 16:18
: 1376117334:0;cat "\n" ### /Users/simont 2013-08-10 16:18
: 1376117339:0;echo "\n" ### /Users/simont 2013-08-10 16:18
: 1376117343:0;echo "\\" ### /Users/simont 2013-08-10 16:19

我不知道你的意思是：

但它使它转义空格和双引号，所以它也是错误的

所以我无法对此进行测试。

于 2013-08-10T06:51:45.247 回答
0

我找到了问题的根源，通过比以前更仔细地阅读 zsh 手册页部分可以看出这一点。

下print：

          -r     Ignore the escape conventions of echo.

因此，我必须对我的 zshrc 进行的唯一更改（我的符号~/.zshrc链接到此zshrc文件）是：

diff --git a/zshrc b/zshrc
index 5e72133..af97c35 100644
--- a/zshrc
+++ b/zshrc
@@ -68,7 +68,7 @@ function zshaddhistory() {
     # do not do anything on common commands

     # do the needful
-    echo "$PWD; $COMMAND_STR; $TTY@$HOST@$(date +%s.%N)" >> ~/.zsh_enhanced_history
+    print -r "$PWD; $COMMAND_STR; $TTY@$HOST@$(date +%s.%N)" >> ~/.zsh_enhanced_history

     # rest is "default" zshaddhistory()
     print -Sr ${COMMAND_STR}
于 2013-08-11T20:37:17.370 回答