emacs - 我如何在 elisp 中编写 walk 代码？

Question

我正在尝试打开一个文件并通读sexp。如果表单的第一个位置有 setq，则遍历表单的其余部分，将 setq 表单中的

;;; File passwords.el.gpg
(setq twitter-password "Secret"
      github-password "Sauce")

我的目标是能够从 teh 文件中的 setq 表单中的对构造一个列表。我怎么开始？

Answer 1

您可以使用流读取文件（从字符串读取），然后进行通常的 elisp 黑客攻击。以下内容并不可靠，但您明白了。在包含您的文件的文件 pwd.el 上，它返回 alist ((github-password . "Sauce") (twitter-password . "Secret"))

(defun readit (file)
  "Read file.  If it has the form (sexp [VAR VALUE]+), return
an alist of the form ((VAR . VALUE) ...)"
  (let* (alist
         (sexp-len
          (with-temp-buffer 
            (insert-file-contents file)
            (read-from-string (buffer-substring 1 (buffer-size)))))
         (sexp (car sexp-len)))
    (when (equal (car sexp) 'setq)
      (setq sexp (cdr sexp))
      (while sexp
        (let* ((l (car sexp))
               (r (cadr sexp)))
          (setq alist (cons (cons l r) alist)
                sexp (cddr sexp)))))
    alist))

(readit "pwd.el")

Answer 2

首先，我支持将密码存储在实际 alist 中的建议，并在必要时根据此设置所需的任何变量。

除此之外，这是另一种尝试解决问题的解决方案。该-partition函数来自我强烈推荐的dash.el库。

您实际上并不需要“走”代码，只需read将其放入并检查其car是否为setq. 表格的其余部分应该是交替的符号和字符串，因此您只需将它们除以 2 即可获得 alist。（请注意，“对”将是正确的列表，而不是肖恩解决方案中的点对）。

(defun setq-form-p (form)
  (eq (car form) 'setq))

(defun read-file (filename)
  (with-temp-buffer
    (insert-file-literally filename)
    (read (buffer-substring-no-properties 1 (point-max)))))

(defun credential-pairs (form)
  (-partition 2 (cdr form)))

(defun read-credentials-alist (filename)
  (let ((form (read-file filename)))
    (credential-pairs form)))

;; usage:
(read-credentials-alist "passwords.el")

或者，如果您已经在 alist 中拥有密码，这就是它的工作方式，就像这样

(defvar *passwords*
  '((twitter-password "Secret")
    (github-password "Sauce")))

然后想将变量设置twitter-password为"Sauce"等等。你只需映射它：

(mapcar #'(lambda (pair)
            (let ((name (car pair))
                  (value (cadr pair)))
              (set name value)))
        *passwords*)