1

我已将 XSLT 从此答案改编并扩展为：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:x="http://schemas.microsoft.com/winfx/2006/xaml/presentation"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt"
    exclude-result-prefixes="msxsl x">

  <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>

  <xsl:template match="x:Section[not(parent::x:Section)]">
    <div>
      <xsl:apply-templates select="node()"/>
    </div>
  </xsl:template>

  <xsl:template match="x:Section">
    <xsl:apply-templates select="node()"/>
  </xsl:template>

  <xsl:template match="x:Paragraph">
    <p>
      <xsl:apply-templates select="node()"/>
    </p>
  </xsl:template>

  <xsl:template match="x:Run">
    <xsl:variable name="style">
      <xsl:if test="@FontStyle='Italic'">
        <xsl:text>font-style:italic;</xsl:text>
      </xsl:if>
      <xsl:if test="@FontWeight='Bold'">
        <xsl:text>font-weight:bold;</xsl:text>
      </xsl:if>
      <xsl:if test="contains(@TextDecorations, 'Underline')">
        <xsl:text>text-decoration:underline;</xsl:text>
      </xsl:if>
      <xsl:if test="@FontSize != ''">
        <xsl:text>font-size:</xsl:text>
        <xsl:value-of select="@FontSize" />
        <xsl:text>pt;</xsl:text>
      </xsl:if>
      <xsl:if test="@FontFamily != ''">
        <xsl:text>font-family:</xsl:text>
        <xsl:value-of select="@FontFamily" />
        <xsl:text>;</xsl:text>
      </xsl:if>
      <xsl:if test="@Foreground-Color != ''">
        <xsl:text>color:</xsl:text>
        <xsl:value-of select="@Foreground-Color"/>
        <xsl:text>;</xsl:text>
      </xsl:if>
    </xsl:variable>
    <span>
      <xsl:if test="normalize-space($style) != ''">
        <xsl:attribute name="style">
          <xsl:value-of select="normalize-space($style)"/>
        </xsl:attribute>
      </xsl:if>
      <xsl:value-of select="text()"/>
    </span>
  </xsl:template>
</xsl:stylesheet>

这个 XSLT 完美地工作，除了这部分：

  <xsl:if test="@Foreground-Color != ''">
    <xsl:text>color:</xsl:text>
    <xsl:value-of select="@Foreground-Color"/>
    <xsl:text>;</xsl:text>
  </xsl:if>

除了前景色，我尝试过颜色和字体颜色，但似乎没有任何效果。

“test=”和“select=”之后提取文本前景色的正确关键字是什么？

4

1 回答 1

2

当您使用 CSS 内联样式创建 HTML 时，这更像是一个 CSS 问题而不是 XSLT 问题。CSS 中正确的属性名确实是color这样部分是正确的。但是，我不知道您的输入格式使用哪些颜色值，以及它们是否等于 CSS 理解的颜色名称。因此，向我们展示一个输入样本并检查 CSS 颜色属性值规范：http ://www.w3.org/TR/CSS2/syndata.html#value-def-color 。

至于属性，基于http://msdn.microsoft.com/en-us/library/system.windows.documents.textelement.foreground.aspx属性可能只是

  <xsl:if test="@Foreground != ''">
    <xsl:text>color:</xsl:text>
    <xsl:value-of select="@Foreground"/>
    <xsl:text>;</xsl:text>
  </xsl:if>

我还没有检查可能的颜色值及其与 CSS 值的匹配。

于 2013-07-31T09:56:30.157 回答