3

我正在尝试计算GS1 校验位并提出以下代码。计算校验位的算法是：

  1. 反转条码
  2. 删除最后一位（计算校验位）
  3. 将数字与第一位，第三位，第五位等数字乘以 3 甚至偶数位乘以 1 相加。
  4. 从最接近的等于或高于十的倍数中减去总和

这听起来很简单，但我想出的解决方案似乎有点不雅。它确实有效，但我想知道是否有更优雅的方式来写这个。

(defn abs "(abs n) is the absolute value of n" [n]
  (cond
   (not (number? n)) (throw (IllegalArgumentException.
                 "abs requires a number"))
   (neg? n) (- n)
   :else n))

(defn sum-seq "adds (first number times 3) with (second number)"
  [coll]
  (+ 
   (* (first coll) 3)
   (second coll)))

(defn sum-digit
  [s]
  (reduce +
  (map sum-seq
  (partition 2 2 '(0) 
  (map #(Integer/parseInt %)
  (drop 2 (clojure.string/split (clojure.string/reverse s) #"")))))))

(defn mod-higher10 "Subtracts the sum from nearest equal or higher multiple of ten"
  [i]
  (if (zero? (rem i 10))
    0
    (- 10(rem i 10))))

(defn check-digit "calculates a GS1 check digit"
  [s]
  (mod-higher10 
   (sum-digit s)))

(= (check-digit "7311518182472") 2)
(= (check-digit "7311518152284") 4)
(= (check-digit "7311518225261") 1)
(= (check-digit "7311518241452") 2)
(= (check-digit "7311518034399") 9)
(= (check-digit "7311518005955") 5)
(= (check-digit "7311518263393") 3)
(= (check-digit "7311518240943") 3)
(= (check-digit "00000012345687") 7)
(= (check-digit "012345670") 0)
4

2 回答 2

6 
(defn check-digit 
  [s] 
  (let [digits        (map #(Integer/parseInt (str %)) s)
        [chk & body]  (reverse digits)
        sum           (apply + (map * body (cycle [3 1])))
        moddiff       (mod (- 10 sum) 10)]
       moddiff))

这个实现使用了我意识到的两个 clojure 成语：

  • let管理局部分解（和重用）
  • map使用第二个集合，作为与问题“相邻”的无限惰性序列。

还对列表进行解构，以便将检查谓词编写为(= moddiff chk).

于 2013-07-29T11:18:33.877 回答
1

线程宏 -> ->> 非常适合链接函数应用程序

(defn to-digits [s] (map #(Integer/parseInt (str %)) s))

(defn check-digit [string]
 (->> string
   to-digits
   reverse rest
   (map * (cycle [3 1]) )
   (apply +)
   (- 10)
   (#(mod % 10))
   ))
于 2013-07-29T21:59:42.560 回答