24

假设我有以下 Turtle 声明：

@prefix : <http://example.org#> .

:ls :list (:a :b :c)

有没有办法获取集合中元素的位置？

例如，使用此查询：

PREFIX :     <http://example.org#>
PREFIX rdf:  <http://www.w3.org/1999/02/22-rdf-syntax-ns#> 

SELECT ?elem WHERE {
 ?x :list ?ls .
 ?ls rdf:rest*/rdf:first ?elem .
}

我得到：

--------
| elem |
========
| :a   |
| :b   |
| :c   |
--------

但我想获得一个查询：

--------------
| elem | pos |
==============
| :a   |  0  |
| :b   |  1  |
| :c   |  2  |
--------------

是否可以？

4

3 回答 3

47

纯 SPARQL 1.1 解决方案

我已经扩展了数据以使问题变得更加困难。让我们在列表中添加一个重复元素，例如，:a在末尾添加一个：

@prefix : <http://example.org#> .

:ls :list (:a :b :c :a) .

然后我们可以使用这样的查询来提取每个列表节点（及其元素）以及该节点在列表中的位置。这个想法是我们可以将列表中的所有单个节点与类似的模式匹配[] :list/rdf:rest* ?node。但是，每个节点的位置是链表头和 之间的中间节点数?node。我们可以通过将模式分解为来匹配每个中间节点

[] :list/rdf:rest* ?mid . ?mid rdf:rest* :node .

然后，如果我们按 分组?node，则不同?mid绑定的数量是?node列表中的位置。因此，我们可以使用以下查询（它还rdf:first获取与每个节点关联的元素（the ））来获取列表中元素的位置：

prefix : <https://stackoverflow.com/q/17523804/1281433/>
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

select ?element (count(?mid)-1 as ?position) where { 
  [] :list/rdf:rest* ?mid . ?mid rdf:rest* ?node .
  ?node rdf:first ?element .
}
group by ?node ?element

----------------------
| element | position |
======================
| :a      | 0        |
| :b      | 1        |
| :c      | 2        |
| :a      | 3        |
----------------------

这是有效的，因为 RDF 列表的结构是这样的链表（其中?head是列表的开头（ 的对象:list），并且是?mid由于模式 的另一个绑定[] :list/rdf:rest* ?mid）：

RDF 列表的图形表示

与 Jena ARQ 扩展的比较

提问者还发布了一个使用 Jena 的 ARQ 扩展来处理 RDF 列表的答案。该答案中发布的解决方案是

PREFIX :     <http://example.org#>
PREFIX rdf:  <http://www.w3.org/1999/02/22-rdf-syntax-ns#> 
PREFIX list: <http://jena.hpl.hp.com/ARQ/list#>

SELECT ?elem ?pos WHERE {
 ?x :list ?ls .
 ?ls list:index (?pos ?elem).
}

这个答案取决于使用 Jena 的 ARQ 并启用扩展，但它更加简洁和透明。不明显的是一个人是否有明显更好的表现。事实证明，对于小列表，差异并不是特别显着，但对于较大的列表，ARQ 扩展具有更好的性能。纯 SPARQL 查询的运行时间很快变得非常长，而使用 ARQ 扩展的版本几乎没有区别。

-------------------------------------------
| num elements | pure SPARQL | list:index |
===========================================
|      50      |    1.1s     |    0.8s    |
|     100      |    1.5s     |    0.8s    |
|     150      |    2.5s     |    0.8s    |
|     200      |    4.8s     |    0.8s    |
|     250      |    9.7s     |    0.8s    |
-------------------------------------------

这些特定值显然会根据您的设置而有所不同，但总体趋势应该在任何地方都可以观察到。由于将来情况可能会发生变化，因此这是我正在使用的特定版本的 ARQ：

$ arq --version
Jena:       VERSION: 2.10.0
Jena:       BUILD_DATE: 2013-02-20T12:04:26+0000
ARQ:        VERSION: 2.10.0
ARQ:        BUILD_DATE: 2013-02-20T12:04:26+0000

因此，如果我知道我必须处理重要大小的列表并且我有可用的 ARQ，我会使用扩展。

于 2013-07-08T15:40:51.970 回答
4

我找到了一种使用 ARQ 中的属性函数库的方法。正如史蒂夫哈里斯所说，这是非标准的。

PREFIX :     <http://example.org#>
PREFIX rdf:  <http://www.w3.org/1999/02/22-rdf-syntax-ns#> 
PREFIX list: <http://jena.hpl.hp.com/ARQ/list#>

SELECT ?elem ?pos WHERE {
 ?x :list ?ls .
 ?ls list:index (?pos ?elem).
}
于 2013-07-08T13:46:03.380 回答
2

TL; DR - 简短回答否，但，长回答是，如果。

简短的回答

并非没有超出标准，除非您的列表长度受限制，否则您可以做一些肮脏的事情，例如：

{ ?x :list (:a) BIND(1 AS ?length) }
UNION
{ ?x :list ([], :a) BIND(2 AS ?length) }
UNION
{ ?x :list ([], [], :a) BIND(3 AS ?length) }
...

等等

一些 RDF 查询引擎具有可在 RDF 列表上运行的非标准函数，但您必须查阅系统的文档。

长答案

这是具有糟糕结构和定义的 RDF 列表的症状。不知何故，我们最终得到了两种不同的表示列表的方式，这两种方式都很难使用！

如果您控制数据，请使用一些更明智的表示，例如

<x> :member [
   rdf:value :a ;
   :ordinal 1 ;
], [
   rdf:value :b ;
   :ordinal 2 ;
], [
   rdf:value :c ;
   :ordinal 3 ;
]
...

然后你可以查询：

{ <x> :member [ rdf:value :a ; :ordinal ?position ] }
于 2013-07-08T11:04:14.300 回答