7

我不知道如何检测静态甚至动态链接的 dll 中的内存泄漏。我只想检测 dll 中的泄漏，我不想在 dll 和应用程序之间共享内存管理器。此外，该 dll与运行时包链接

我的示例 dll 如下所示：

library dll;
uses
  fastmm4,
  System.SysUtils,
  System.Classes;
{$R *.res}
procedure MyInit; stdcall;
Begin
  TObject.Create;
End;
exports MyInit;
begin
end.

应用程序 dpr：

program app;

uses
  //fastmm4,
  Vcl.Forms,
  main in 'main.pas' {Form1};

{$R *.res}

begin
  Application.Initialize;
  Application.MainFormOnTaskbar := True;
  Application.CreateForm(TForm1, Form1);
  Application.Run;
end.

注意：如果我取消注释 fastmm4，我可以检测到由应用程序 (TStringList.Create) 引起的 memleak，但不能检测到 dll 中的泄漏。

并在应用程序主单元中：

unit main;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    LDLLHandle: HModule;
    LShowProc: TProcedure;
  end;

var
  Form1: TForm1;

{$ifdef static}
procedure MyInit; stdcall; external 'dll.dll';
{$endif}

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  TStringList.Create;
  {$ifdef static}
  MyInit;
  {$else}
  LDLLHandle := LoadLibrary('dll.dll');
  if LDLLHandle <> 0 then
  begin
    try
      LShowProc := GetProcAddress(LDLLHandle, 'MyInit');
      if Assigned(LShowProc) then
        LShowProc;
    finally
      FreeLibrary(LDLLHandle);
    end;
  end;
  {$endif}
end;

end.

我希望 FastMM 在调用 FreeLibrary 时或在程序退出时生成报告，如果静态加载 dll，但没有任何反应。

在FastMM4Options.inc我另外只设置了FullDebugMode和ClearLogFileOnStartup，并且FastMM_FullDebugMode.dll在输出目录中。

我在 github 上创建了一个存储库。我错过了什么？

4

2 回答 2

5

您的 DLL 未报告泄漏的原因源于 FastMM 关闭中的此代码：

  CheckBlocksOnShutdown(
  {$ifdef EnableMemoryLeakReporting}
        True
    {$ifdef RequireIDEPresenceForLeakReporting}
        and DelphiIsRunning
    {$endif}
    {$ifdef RequireDebuggerPresenceForLeakReporting}
        and ((DebugHook <> 0)
        {$ifdef PatchBCBTerminate}
        or (Assigned(pCppDebugHook) and (pCppDebugHook^ <> 0))
        {$endif PatchBCBTerminate}
        )
    {$endif}
    {$ifdef ManualLeakReportingControl}
        and ReportMemoryLeaksOnShutdown
    {$endif}
  {$else}
        False
  {$endif}
  );

在您的选项中，RequireDebuggerPresenceForLeakReporting已定义。更何况，在DLL中，DebugHook等于0，大概是因为你调试的是应用程序而不是DLL。这意味着您调用CheckBlocksOnShutdownpass False。这False会禁用泄漏报告。

您可以通过取消定义来解决此问题RequireDebuggerPresenceForLeakReporting。

于 2013-07-05T10:26:10.340 回答
-1

我只是在 Delphi2010 - win7 上使用 Fast Memory Manager 4.97 版本测试它

  1. FastMM4 是 .dpr（项目和 dll）的“使用”子句中的第一个单元
  2. 'ShareMM' 选项已启用
  3. 'AttemptToUseSharedMM' 选项已启用
  4. 'EnableMemoryLeakReporting' 选项已启用

在exe的文件夹中添加FastMM_FullDebugMode.dll

还有一个测试演示“动态加载的 DLL”这个演示没有 ShareMem。我必须启用“ShareMM”和“AttemptToUseSharedMM”选项并添加 FastMM_FullDebugMode.dll 以获得 FastMM 的泄漏报告。

于 2013-07-05T08:04:10.110 回答