11

这是我的第一个批处理程序，我一直在网上搜索，但仍在努力编写解决方案。

我有以下 CSV 文件：

"RH",2013/06/15 02:14:58 -0400,"X","LQ3SUEEWPWKL6",005,
"FH",01
"SH",2013/06/14 00:00:00 -0400,2013/06/14 23:59:59 -0400,"LQ3SUEEWPWKL6",""
"CH","TransactionID","InvoiceID", 
......

我正在尝试编写一个简单的程序来执行以下操作：

  • 如果 column1 = "RH"，则提取 column2 值 (2013/06/15 02:14:58 -0400)
  • 如果 column1 = "SH"，则提取 column4 值 (LQ3SUEEWPWKL6)

和管道输出到一个文件。

到目前为止，这是我的代码，但 if 条件对我不起作用

@echo off
:: Set input file in variable
::Set _InputFile=%1

:: Store input line into different variables
FOR /F "tokens=1-18* delims=," %%A IN (%_InputFile%) DO (
Set _var1=%%A
Set _var2=%%B
Set _var3=%%C
Set _var4=%%D
Set _var5=%%E
Set _var6=%%F
Set _var7=%%G
Set _var8=%%H
Set _var9=%%I
Set _var10=%%J
Set _var11=%%K
Set _var12=%%L
Set _var13=%%M
Set _var14=%%N
Set _var15=%%O
Set _var16=%%P
Set _var17=%%Q
Set _var18=%%R


IF "%_var1%"=="RH" echo %var2%

)

我的 CSV 文件在 Excel 和记事本中看起来不错，但是当我执行脚本以显示第一个变量时，看起来第一条记录的“RH”之前有一些垃圾字符 - 我无法绕过它，因为我需要提取额外的列如果 var1 = "RH" 的数据：

"RH"
FH
01
SH
CH
TransactionID,PaymentTrackingID,
SF
SF
SC
RF
CAD,CR,0
RF
USD,CR,0
RC
FF
4

4 回答 4

10 
(
FOR /F "tokens=1-18* delims=," %%A IN (%_InputFile%) DO (
  if "%%~A"=="RH" echo %%~B
  if "%%~A"=="SH" echo %%~D
 )
)>youroutputfilename

应该可以工作-无需将所有值分配给不同的变量-但是如果您打算使用它们，那么

FOR /F "tokens=1-18* delims=," %%A IN (%_InputFile%) DO (
...
Set _var17=%%Q
Set _var18=%%R
CALL :PROCESS
)
...
GOTO :EOF

:PROCESS
IF %_var1%=="RH" echo %_var2%
IF %_var1%=="SH" echo %_var4%
GOTO :EOF

请注意，使用此方法，由于您分配%%x给_varxthen if%%x被引用，引号将包含在分配的值中。要删除封闭引号（如果存在），请使用SET _varx=%%~x.

OP 问题的附录 20130703-1956Z

@ECHO OFF
SETLOCAL
SET _Inputfile=u:\noname1.txt
(
FOR /F "tokens=1-18* delims=," %%A IN (%_InputFile%) DO (
  SET "RH="
  SET "SH="
  ECHO(%%A|FINDSTR /l /c:"\"RH\"" >NUL
  IF NOT ERRORLEVEL 1 SET RH=Y
  ECHO(%%A|FINDSTR /l /c:"\"SH\"" >NUL
  IF NOT ERRORLEVEL 1 SET SH=Y
  if DEFINED RH echo %%~B
  if DEFINED SH echo %%~D
 )
)>u:\youroutputfilename
TYPE u:\youroutputfilename
del u:\youroutputfilename
echo========First way

(
FOR /F "tokens=1-18* delims=," %%A IN (%_InputFile%) DO (
  SET _var1=%%A
  SET "RH="
  SET "SH="
  CALL :process
  if DEFINED RH echo %%~B
  if DEFINED SH echo %%~D
 )
)>u:\youroutputfilename

TYPE u:\youroutputfilename
del u:\youroutputfilename
echo========Second way

SETLOCAL ENABLEDELAYEDEXPANSION 
(
FOR /F "tokens=1-18* delims=," %%A IN (%_InputFile%) DO (
  SET _var1=%%A
  IF "!_var1:~-4!"==""RH"" echo %%~B
  IF "!_var1:~-4!"==""SH"" echo %%~D
 )
)>u:\youroutputfilename

TYPE u:\youroutputfilename
del u:\youroutputfilename
echo========Third way
ENDLOCAL

GOTO :EOF

:process
IF "%_var1:~-4%"==""RH"" SET RH=Y
IF "%_var1:~-4%"==""SH"" SET SH=Y
GOTO :EOF
于 2013-07-04T15:58:18.927 回答
4

你有一个解析问题。首先用 结束 for 循环)，之后您可以使用新变量：

@echo off
:: Set input file in variable
::Set _InputFile=%1

:: Store input line into different variables
FOR /F "tokens=1-18* delims=," %%A IN (%_InputFile%) DO (
    Set "_var1=%%A"
    Set "_var2=%%B"
    Set "_var3=%%C"
    Set "_var4=%%D"
    Set "_var5=%%E"
    Set "_var6=%%F"
    Set "_var7=%%G"
    Set "_var8=%%H"
    Set "_var9=%%I"
    Set "_var10=%%J"
    Set "_var11=%%K"
    Set "_var12=%%L"
    Set "_var13=%%M"
    Set "_var14=%%N"
    Set "_var15=%%O"
    Set "_var16=%%P"
    Set "_var17=%%Q"
    Set "_var18=%%R"
)

IF "%_var1%"=="RH" echo %var2%
于 2013-07-04T15:48:40.853 回答
3

您需要启用延迟扩展：

@echo off

setlocal EnableDelayedExpansion

set "_InputFile=..."

for /f "tokens=1-18* delims=," %%A in (%_InputFile%) do (
  Set _var1=%%A
  Set _var2=%%B
  ...

  if "!_var1!"=="RH" echo !_var2!
)
于 2013-07-04T15:40:58.353 回答
2

由于没有答案“为什么我的行以∩╗┐“RH”开头”，我会做一些坟墓挖掘。

因此，∩╗┐ 来自 BOM（字节顺序标记），表示文件为 UTF，以及字节的写入方式（如有必要）。答案是：你可以使用

if x%_var1:RH=%x NEQ x%_var1%x (echo %_var2%)

这将检查 RH 是否在 %_var1% 中（如果在 var 中替换 RH 后，它没有改变，RH 不在 var 中）这意味着，Bom 是否在这里并不重要。但是，如果您想要完全匹配，则会遇到问题。

另一种处理方法是不在文件中包含 bom，这意味着在没有 BOM 的情况下以 ASCII 或 UTF-8 保存；或者使用工具从 UTF-8 文件中去除 bom。

于 2016-10-12T11:49:40.617 回答