2

德尔福 Xe4。表单、ActionManager、ImageList（带有 32x32 图标）、ActionMainMenuBar。

我无法确保图标正确显示。你该怎么办？

图1

同时，如果我应用任何 vcl 风格的装饰，它显示得很好。但如果默认为“Windows”样式，则文字会移出图标。帮助。

图2

图3

图4

对不起英语不好。

4

1 回答 1

6

这是一个有效的问题，TActionMainMenuBar旨在将自定义图标大小处理为菜单图像，就像本机菜单可以很好地处理它们一样。可以在代码中的注释中找到一种指示，在下面的 VCL 代码中您可以找到注释16 is standard image size so adjust for larger images。

我相信，错误代码TCustomMenuItem.CalcBounds在“ActnMenus.pas”中。以下摘录来自 D2007。请注意下面我用一些感叹号评论的行。上层类在其方法TCustomActionControl中计算出文本和图像的位置后，用上述语句中的硬编码24将其破坏。CalcLayoutTCustomMenuItem

procedure TCustomMenuItem.CalcBounds;
var
  AWidth, AHeight: Integer;
  NewTextBounds: TRect;
  ImageSize: TPoint;
  ImageOffset: Integer;
begin
  inherited CalcBounds;
  ImageSize := GetImageSize;
  AHeight := FCYMenu;
  if Separator then
    AHeight := FCYMenu div 3 * 2
  else
    // 16 is standard image size so adjust for larger images
    if ImageSize.Y > 16 then
      AHeight := ImageSize.Y + 4;
  if ActionClient = nil then exit;
  if ImageSize.X <= 16 then
    ImageOffset := 24
  else
    ImageOffset := ImageSize.X + 6;  // Leave room for an image frame
  NewTextBounds := TextBounds;
  OffsetRect(NewTextBounds, 24 - TextBounds.Left,          // <- !!!!!
    AHeight div 2 - TextBounds.Bottom div 2 - 1);
  TextBounds := NewTextBounds;
  ShortCutBounds := Rect(0,0,0,0);
  if ActionClient.ShortCut <> 0 then
  begin
    Windows.DrawText(Canvas.Handle, PChar(ActionClient.ShortCutText), -1,
      FShortCutBounds, DT_CALCRECT);
    // Left offset is determined when the item is painted to make it right justified
    FShortCutBounds.Top := TextBounds.Top;
    FShortCutBounds.Bottom := TextBounds.Bottom;
    AWidth := TextBounds.Right + FShortCutBounds.Right + ImageOffset + Spacing;
  end
  else
    AWidth := TextBounds.Right + TextBounds.Left;
  SetBounds(Left, Top, AWidth, AHeight);
end;


24是基于具有 16 或更少像素宽度的图像的假设。应该使用的是ImageOffset上面几行计算的值。代替

  OffsetRect(NewTextBounds, 24 - TextBounds.Left,
    AHeight div 2 - TextBounds.Bottom div 2 - 1);

和

  OffsetRect(NewTextBounds, ImageOffset - TextBounds.Left,
    AHeight div 2 - TextBounds.Bottom div 2 - 1);

你会有这样的东西：

下拉菜单

不过，您会注意到其他一些奇怪的地方，没有图像的项目仍在适应小型图像布局。IMO 所有菜单项都应具有相同的基本布局，但操作菜单的设计允许单个项目的不同布局。另一件奇怪的事情是带有图像（'Action6'）的项目的选中状态，尽管我不确定我是否在这里缺少设置，或者它是否符合错误的条件。

于 2013-07-08T22:36:41.587 回答