0

我正在使用推力矢量。

我正在寻找一种优雅的方法来使用“镜像”排序重新排序推力设备矢量，（给出的示例，在 Thrust 中找不到任何函数）

例如，假设我的向量包含一个结构，每个结构包含几个数字。我的向量如下所示

[1,2]   [5,4]    [-2,5]     [6,1]     [2,6]

镜像重新排序操作后，我想收到以下向量（第一个元素与第 n 个元素切换）（第 i 个元素与 ni 元素切换等）

[2,6]   [6,1]    [-2,5]    [5,4]    [1,2]

Thrust 有什么优雅的方法吗？

顺便说一句，我正在考虑给每个结构一个唯一的 ID 编号并根据该编号进行排序，这样我就可以“镜像”使用排序对向量进行重新排序。

4

2 回答 2

2

使用thrust::reverse：

#include <thrust/device_vector.h>
#include <thrust/reverse.h>
#include <thrust/pair.h>
#include <iostream>

int main()
{
  thrust::device_vector<thrust::pair<int,int> > vec;

  vec.push_back(thrust::make_pair( 1,2));
  vec.push_back(thrust::make_pair( 5,4));
  vec.push_back(thrust::make_pair(-2,5));
  vec.push_back(thrust::make_pair( 6,1));
  vec.push_back(thrust::make_pair( 2,6));

  std::cout << "input: " << std::endl;
  for(int i = 0; i < vec.size(); ++i)
  {
    thrust::pair<int,int> x = vec[i];
    std::cout << " [" << x.first << ", " << x.second << "]";
  }
  std::cout << std::endl;

  thrust::reverse(vec.begin(), vec.end());

  std::cout << "output: " << std::endl;
  for(int i = 0; i < vec.size(); ++i)
  {
    thrust::pair<int,int> x = vec[i];
    std::cout << " [" << x.first << ", " << x.second << "]";
  }
  std::cout << std::endl;

  return 0;
}

输出：

$ nvcc reverse.cu -run
input: 
 [1, 2] [5, 4] [-2, 5] [6, 1] [2, 6]
output: 
 [2, 6] [6, 1] [-2, 5] [5, 4] [1, 2]
于 2013-06-13T06:14:45.327 回答
0

push::gather允许根据映射（向量）将源向量元素任意复制到目标向量元素。

这是一个工作示例：

#include <stdio.h>
#include <thrust/host_vector.h>
#include <thrust/device_vector.h>
#include <thrust/gather.h>
#include <thrust/sequence.h>

#define DSIZE 7

struct myStruct {
  int x;
  int y;
};

int main(){

  // create input data
  thrust::host_vector<myStruct> h(DSIZE);
  for (int i=0; i< DSIZE; i++){
    h[i].x = 2*i;
    h[i].y = (2*i)+1;
    }

  // create map
  thrust::device_vector<int> map(DSIZE);
  thrust::sequence(map.begin(), map.end(), DSIZE-1, -1);

  //move to device
  thrust::device_vector<myStruct> d = h;
  thrust::device_vector<myStruct> d_result(DSIZE);

  thrust::gather(map.begin(), map.end(), d.begin(), d_result.begin());

  //move to host
  thrust::host_vector<myStruct> h_result = d_result;

  for (int i = 0; i < DSIZE; i++){
    printf("result[%d].x = %d, result[%d].y = %d\n", i, h_result[i].x, i, h_result[i].y);
    }
  return 0;
}
于 2013-06-12T13:22:05.137 回答