2

我有一段处理代码，它似乎正在设置一个随机傅立叶级数。不幸的是，尽管我努力提高我的数学技能，但我不知道它在做什么，我发现的文章也没有太大帮助。

我正在尝试扩展此代码，以便可以绘制一条与下面代码创建的斜率上的点相切的线。我能找到的最接近回答这个问题的是数学论坛。不幸的是，我真的不明白正在讨论什么，或者它是否真的与我的情况有关。

任何有关我将如何计算该曲线上特定点的切线的帮助将不胜感激。

更新截至 2013 年 6 月 17 日

我一直在尝试解决这个问题，但没有取得多大成功。这是我能做的最好的事情，我怀疑我是否正确地应用了导数来找到切线（或者即使我已经正确地找到了该点的导数）。另外，我开始担心即使其他一切都正确，我也没有正确地画线。如果有人可以就此提供意见，我将不胜感激。 

final int w = 800;
final int h = 480;
double[] skyline;
PImage img;
int numOfDeriv = 800;
int derivModBy = 1; //Determines how many points will be checked
int time;
int timeDelay = 1000;
int iter;
double[] derivatives;

void setup() {
  noStroke();
  size(w, h);
  fill(0,128,255);
  rect(0,0,w,h);
  int t[] = terrain(w,h);
  fill(77,0,0);
  for(int i=0; i < w; i++){
    rect(i, h, 1, -1*t[i]);
  }
  time = millis();
  timeDelay = 100;
  iter =0;
  img = get();
}

void draw() {
  int dnum = 0; //Current position of derivatives
  if(iter == numOfDeriv) iter = 0;
  if (millis() > time + timeDelay){
        image(img, 0, 0, width, height);
        strokeWeight(4);
        stroke(255,0,0);        
        point((float)iter*derivModBy, height-(float)skyline[iter*derivModBy]);
        strokeWeight(1);
        stroke(255,255,0);
        print("At x = ");
        print(iter);
        print(", y = ");
        print(skyline[iter]);
        print(", derivative = ");
        print((float)derivatives[iter]);
        print('\n');
        lineAngle(iter, (int)(height-skyline[iter]), (float)derivatives[iter], 100);
        lineAngle(iter, (int)(height-skyline[iter]), (float)derivatives[iter], -100);
        stroke(126);
        time = millis();
        iter += 1;
    }
}

void lineAngle(int x, int y, float angle, float length)
{
  line(x, y, x+cos(angle)*length, y-sin(angle)*length);
}

int[] terrain(int w, int h){

    width = w;
    height = h;

    //min and max bracket the freq's of the sin/cos series
    //The higher the max the hillier the environment
    int min = 1, max = 6;

    //allocating horizon for screen width
    int[] horizon = new int[width];
    skyline =  new double[width];
    derivatives = new double[numOfDeriv];

    //ratio of amplitude of screen height to landscape variation
    double r = (int) 2.0/5.0;

    //number of terms to be used in sine/cosine series
    int n = 4;

    int[] f = new int[n*2];

    //calculating omegas for sine series
    for(int i = 0; i < n*2 ; i ++){
      f[i] = (int) random(max - min + 1) + min;
    }

    //amp is the amplitude of the series
    int amp =  (int) (r*height);
    int dnum = 0; //Current number of derivatives    
    for(int i = 0 ; i < width; i ++){
      skyline[i] = 0;
      double derivative = 0.0;
      for(int j = 0; j < n; j++){
         if(i % derivModBy == 0){
            derivative += ( cos( (f[j]*PI*i/height) * f[j]*PI/height) - 
                        sin(f[j+n]*PI*i/height) * f[j+n]*PI/height);
         }

        skyline[i] += ( sin( (f[j]*PI*i/height) ) +  cos(f[j+n]*PI*i/height) );
        }
      skyline[i] *= amp/(n*2);
      skyline[i] += (height/2);
      skyline[i] = (int)skyline[i];
      horizon[i] = (int)skyline[i];
      derivative *= amp/(n*2);
      if(i % derivModBy == 0){
        derivatives[dnum++] = derivative;
        derivative = 0;
      }
    }

    return horizon;
}

void reset() {
  time = millis();
}
4

2 回答 2

3

好吧，在这种特殊情况下，您似乎不需要对傅里叶级数有太多了解，只需它具有以下形式：

    A0 + A1*cos(x) + A2*cos(2*x) + A3*cos(3*x) +... + B1*sin(x) + B2*sin(x) +...

通常给你一个函数f(x)，你需要找到 和 的值，An这样Bn傅里叶级数会在某个区间内收敛到你的函数（当你添加更多项时）[a, b]。

然而，在这种情况下，他们想要一个看起来像不同的块和坑（或上下文可能暗示的山丘和山谷）的随机函数，因此他们从最小值和最大值之间的傅立叶级数中选择随机项，并将它们的系数设置为 1（并且在概念上0 否则）。它们还满足于 4 个正弦项和 4 个余弦项的傅立叶级数（这肯定比无限数量的项更容易管理）。这意味着他们的傅立叶级数最终看起来像是不同频率的不同正弦和余弦函数加在一起（并且都具有相同的幅度）。

如果您回想一下，找到它的导数很容易：

    sin(n*x)' = n * cos(x)
    cos(n*x)' = -n * sin(x)
    (f(x) + g(x))' = f'(x) + g'(x)

所以计算导数的循环看起来像：

    for(int j = 0; j < n; j++){
        derivative += ( cos( (f[j]*PI*i/height) * f[j]*PI/height) - \
                        sin(f[j+n]*PI*i/height) * f[j+n]*PI/height);
    }

在某些时候i（注意导数是相对于，i因为这是代表我们这里的 x 位置的变量）。

希望有了这个，你应该能够计算出一点的切线方程i。

更新
在您这样做的时候，您skyline[i] *= amp/(n*2);还必须相应地调整您的衍生产品，derivative *= amp/(n*2);但是您的衍生产品在您这样做时不需要调整skyline[i] += height/2;

于 2013-06-11T19:49:07.833 回答
0

我通过 processing.org form 上的“quarks”收到了这个问题的答案。本质上，问题是我取的是系列中每一项的导数，而不是取整个系列之和的导数。另外，无论如何我都没有正确应用我的结果。

这是quarks 提供的代码，它最终解决了这个问题。

final int w = 800;
final int h = 480;
float[] skyline;
PImage img;
int numOfDeriv = 800;
int derivModBy = 1; //Determines how many points will be checked
int time;
int timeDelay = 1000;
int iter;
float[] tangents;

public void setup() {
  noStroke();
  size(w, h);
  fill(0, 128, 255);
  rect(0, 0, w, h);
  terrain(w, h);
  fill(77, 0, 0);
  for (int i=0; i < w; i++) {
    rect(i, h, 1, -1*(int)skyline[i]);
  }
  time = millis();
  timeDelay = 100;
  iter =0;
  img = get();
}

public void draw() {
  if (iter == numOfDeriv) iter = 0;
  if (millis() > time + timeDelay) {
    image(img, 0, 0, width, height);
    strokeWeight(4);
    stroke(255, 0, 0);        
    point((float)iter*derivModBy, height-(float)skyline[iter*derivModBy]);
    strokeWeight(1);
    stroke(255, 255, 0);
    print("At x = ");
    print(iter);
    print(", y = ");
    print(skyline[iter]);
    print(", derivative = ");
    print((float)tangents[iter]);
    print('\n');
    lineAngle(iter, (int)(height-skyline[iter]), (float)tangents[iter], 100);
    lineAngle(iter, (int)(height-skyline[iter]), (float)tangents[iter], -100);
    stroke(126);
    time = millis();
    iter += 1;
  }
}

public void lineAngle(int x, int y, float angle, float length) {
  line(x, y, x+cos(angle)*length, y-sin(angle)*length);
}

public void terrain(int w, int h) {      
  //min and max bracket the freq's of the sin/cos series
  //The higher the max the hillier the environment
  int min = 1, max = 6;
  skyline =  new float[w];
  tangents = new float[w];
  //ratio of amplitude of screen height to landscape variation
  double r = (int) 2.0/5.0;
  //number of terms to be used in sine/cosine series
  int n = 4;
  int[] f = new int[n*2];
  //calculating omegas for sine series
  for (int i = 0; i < n*2 ; i ++) {
    f[i] = (int) random(max - min + 1) + min;
  }
  //amp is the amplitude of the series
  int amp =  (int) (r*h);
  for (int i = 0 ; i < w; i ++) {
    skyline[i] = 0;
    for (int j = 0; j < n; j++) {
      skyline[i] += ( sin( (f[j]*PI*i/h) ) +  cos(f[j+n]*PI*i/h) );
    }
    skyline[i] *= amp/(n*2);
    skyline[i] += (h/2);
  }
  for (int i = 1 ; i < w - 1; i ++) {
    tangents[i] = atan2(skyline[i+1] - skyline[i-1], 2);
  }
  tangents[0] = atan2(skyline[1] - skyline[0], 1);
  tangents[w-1] = atan2(skyline[w-2] - skyline[w-1], 1);
}

void reset() {
  time = millis();
}
于 2013-06-19T21:27:18.150 回答