multithreading - Perl 线程共享数据

Question

在我的脚本中，有 n 个工作线程 (0,1..n-1)，每个工作线程处理以下数组的第 N 个项目。输入数组用于向线程提供输入，输出数组接受线程的输出。线程不会访问数组的其他项。在那种情况下，我应该将数组声明为 shared 吗？

my @ThreadInput   :shared=();
my @ThreadOutput  :shared=();

Answer 1

（我将命名“调用者”填充@ThreadInput和使用的线程@ThreadOutput。）

Perl 变量不会在线程之间共享，除非用:shared. 每个线程都会获得一份未标记的变量副本:shared。

所以，

@ThreadInput如果调用者在工人启动之前填充，@ThreadInput则不需要共享，但如果是，它将避免为每个工人创建数组的副本。

@ThreadInput如果调用者在工人启动后填充，则@ThreadInput必须共享。如果不是，调用者的更改@ThreadInput不会影响工作人员的副本。

@ThreadOutput必须共享。如果不是，则工作人员的更改@ThreadOutput不会影响调用者的副本。

---

使用该模型重用工人将非常困难。您可能应该使用类似以下的内容：

use threads;
use Thread::Queue 1.03;   # or Thread::Queue::Any

use constant NUM_WORKERS => ...;

sub handle_request {
    my ($request) = @_;
    return ...response...;
}

{
   my $request_q  = Thread::Queue->new();
   my $response_q = Thread::Queue->new();

   my @threads;
   my $threads;
   for (1..NUM_WORKERS) {
      ++$threads;
      push @threads, async {
         while (my $request = $request_q->dequeue()) {
            $response_q->enqueue([ $request => handle_request($request) ]);
         }

         $response_q->enqueue(undef);
      };
   }

   ... Add stuff to queue $request_q->enqueue(...) ...

   $request_q->end();  # Can be done later if you want to add more items later.

   while ($threads && my $job = $response_q->dequeue()) {
      if (!defined($job)) {
         --$threads;
         next;
      }

      my ($request, $response) = @$job;
      ... handle response ...
   }

   $_->join for @threads;
}