6

在 VBScript 中，我想获取按创建日期排序的文件夹中的文件列表。我看到为了做到这一点，我需要使用记录集（对我来说似乎有点过头了）或自己对集合进行排序（我想我可以避免它，我希望我的代码更短）。

因为我是创建文件的人，所以我使用以日期开头的名称（yyyy_mm_dd）创建它们，所以我认为，如果我可以得到至少按名称排序的文件，那么我就准备好了。不幸的是，来自 FileSystemObject 的 Files 集合的 MSDN 文档没有说明集合的顺序。有谁知道其他一些秘密文件或类似的东西可以更具体？

4

2 回答 2

13

是否真的太多代码无法排序？

set fso = CreateObject("Scripting.FileSystemObject")

Set outputLines = CreateObject("System.Collections.ArrayList")
for each f in fso.GetFolder(".").files
  outputLines.Add f.Name
next
outputLines.Sort() ' 5 lines...

For Each outputLine in outputLines
  set file = fso.GetFolder(".").files.item (outputLine&"")
  Wscript.Echo file.name ' TODO: your thing here
Next
于 2013-06-04T17:18:05.237 回答
9

如果您想按特定顺序获取文件夹中的文件，则必须自己完成。如果您不喜欢 ADO 记录集或使用可排序的 .NET 集合，您可以使用（.Run、.Exec）并处理dir /A:-D /B /O:D /T:C（无文件夹、裸格式（无标题/摘要）、订单：日期、时间域：创作）。

更新：

虽然我当然可以展示 .Files 集合交付其按名称排序的元素的示例，但盖茨先生明确表示：

信息：FileSystemObject 的限制... 无法对文件集合中的文件名进行排序 - 您可以遍历 Files 集合中的 File 对象以获取文件夹中文件的列表。但是，文件对象未排序。您需要使用排序例程对 Files 集合中的 File 对象进行排序。

简约的演示代码显示：如果你想使用 shell 功能，你需要一个 shell (%comspec%) - 比如内在命令：

Option Explicit

Dim goFS  : Set goFS = CreateObject("Scripting.FileSystemObject")
Dim goWS  : Set goWS = CreateObject("WScript.Shell")
Dim csDir : csDir = "c:\temp"

WScript.Quit demoSF()

Function demoSF()
  demoSF = 0
  Dim aDSOrd : aDSOrd = getDSOrd(csDir, "%comspec% /c dir /A:-D /B /O:D /T:C """ & csDir & """")
  Dim oFile
  For Each oFile In aDSOrd
      WScript.Echo oFile.DateCreated, oFile.Name
  Next
End Function ' demoSF

Function getDSOrd(sDir, sCmd)
  Dim dicTmp : Set dicTmp = CreateObject("Scripting.Dictionary")
  Dim oExec  : Set oExec  = goWS.Exec(sCmd)
  Do Until oExec.Stdout.AtEndOfStream
     dicTmp(goFS.GetFile(goFS.BuildPath(sDir, oExec.Stdout.ReadLine()))) = Empty
  Loop
  If Not oExec.Stderr.AtEndOfStream Then
     WScript.Echo "Error:", oExec.Stderr.ReadAll()
  End If
  getDSOrd = dicTmp.Keys()
End Function

输出：

cscript 16895525.vbs
07.10.1998 15:31:34 TlbInf32.chm
..
09.10.2008 22:40:29 sqlce.sql
09.10.2008 22:40:29 gltsqlcopytest.sdf
05.11.2008 20:11:39 Vorfuehrung.class
..
28.03.2011 20:23:36 Program.cs
.
01.10.2012 10:10:10 KyXHDe.chm
于 2013-06-03T11:34:48.987 回答