javascript - WinForms 应用程序中的地理位置

Question

我想创建一个 WinForms 应用程序，它可以像 Web 浏览器使用 javascript 函数一样检测位置navigator.geolocation.getCurrentPosition(showPosition);

有没有办法直接在 WinForms 中做到这一点？

我认为我可以使用 WebBrowser 控件来执行此操作，但我不相信这支持地理定位（除非有人知道吗？）

显然 Gecko 浏览器确实支持地理定位，但这对我来说不是一个选项，因为客户端可能安装了不同的 firefox 版本。

Answer 1

你应该使用Geckofx

您还需要确保 geckofx 版本与正确的 xulrunner/firefox 版本完全匹配。

GeoLocation 在 geckofx 中还没有很好的 C# 包装类，但您可以使用 xpcom C# 互操作来访问它。

    var instance = Xpcom.CreateInstance<nsIGeolocationProvider>("@mozilla.org/geolocation/provider;1");

Answer 2

我没用过，但微软有一个Windows.Devices.Geolocation API，虽然它是用于 Windows 8 的。

对于 Windows 7，他们似乎有一个 Sensor API，这里有一些示例代码。

Answer 3

归功于 Alex Filipovici在这个问题上给出的答案：C# 桌面应用程序不共享我的物理位置

下面是转换为VB的代码：

网络服务器类：

Imports System
Imports System.Collections.Generic
Imports System.Linq
Imports System.Net
Imports System.Text
Imports System.Threading

Public Class WebServer
    Private ReadOnly _listener As New HttpListener()
    Private Shared _staticContent As String

    Public Sub New(ByVal prefixes() As String, ByVal content As String)
        _staticContent = content
        For Each s As String In prefixes
            _listener.Prefixes.Add(s)
        Next s
        _listener.Start()
    End Sub

    Public Sub New(ByVal content As String, ByVal ParamArray prefixes() As String)
        Me.New(prefixes, content)
    End Sub

    Public Sub Run()
        ThreadPool.QueueUserWorkItem(Sub(o)
                                         Try
                                             Do While _listener.IsListening
                                                 ThreadPool.QueueUserWorkItem(Sub(c)
                                                                                  Dim ctx = TryCast(c, HttpListenerContext)
                                                                                  Try
                                                                                      Dim buf() As Byte = Encoding.UTF8.GetBytes(_staticContent)
                                                                                      ctx.Response.ContentLength64 = buf.Length
                                                                                      ctx.Response.OutputStream.Write(buf, 0, buf.Length)
                                                                                  Catch
                                                                                  Finally
                                                                                      ctx.Response.OutputStream.Close()
                                                                                  End Try
                                                                              End Sub, _listener.GetContext())
                                             Loop
                                         Catch
                                         End Try
                                     End Sub)
    End Sub

    Public Sub [Stop]()
        _listener.Stop()
        _listener.Close()
    End Sub

End Class

表格代码：

Imports System.Reflection
Imports System.Net
Imports System.Threading
Imports System.Text

Public Class Form1
    Dim _ws As WebServer
    Dim _webbrowser1 As WebBrowser

    Public Sub New()
        InitializeComponent()
        _webBrowser1 = New WebBrowser()
        _webBrowser1.Visible = False
        _webBrowser1.ScriptErrorsSuppressed = True
        Dim location = System.Reflection.Assembly.GetExecutingAssembly().Location
        _webBrowser1.Navigate(System.IO.Path.GetDirectoryName(System.Reflection.Assembly.GetExecutingAssembly().Location) & "\test1.html")
        AddHandler _webBrowser1.DocumentCompleted, AddressOf webBrowser1_DocumentCompleted
    End Sub

    Async Sub webBrowser1_DocumentCompleted(sender As Object, e As WebBrowserDocumentCompletedEventArgs)
        If _ws Is Nothing Then
            Dim html = _webBrowser1.Document.GetElementsByTagName("html")
            Dim response = html(0).OuterHtml
            _ws = New WebServer(response, "http://localhost:9999/")
            _ws.Run()
            _webBrowser1.Navigate("http://localhost:9999/")
        Else
            Dim latitude As String = ""
            Dim longitude As String = ""

            Await Task.Factory.StartNew(Sub()
                                            While String.IsNullOrEmpty(latitude)
                                                System.Threading.Thread.Sleep(1000)

                                                If Me.InvokeRequired Then
                                                    Me.Invoke(DirectCast(Sub()
                                                                             Dim latitudeEl = _webbrowser1.Document.GetElementById("latitude")
                                                                             Dim longitudeEl = _webbrowser1.Document.GetElementById("longitude")

                                                                             latitude = latitudeEl.GetAttribute("value")
                                                                             longitude = longitudeEl.GetAttribute("value")

                                                                         End Sub, MethodInvoker))
                                                End If
                                            End While

                                        End Sub)
            txtLocation.Text = String.Format("{0},{1}", latitude, longitude)
        End If
    End Sub
End Class

test1.html 文件

<html xmlns="http://www.w3.org/1999/xhtml">
<head runat="server">
    <title></title>
    <meta http-equiv="X-UA-Compatible" content="IE=10" />
    <script type="text/javascript">
        window.onload = function () {
            var latitude = document.getElementById("latitude");
            var longitude = document.getElementById("longitude");

            function getLocation() {
                if (navigator.geolocation) {
                    navigator.geolocation.getCurrentPosition(showPosition);
                }
                else { }
            }
            function showPosition(position) {
                latitude.value = position.coords.latitude;
                longitude.value = position.coords.longitude;
            }
            getLocation();
        }
    </script>
</head>
<body>
    <input type="hidden" id="latitude" />
    <input type="hidden" id="longitude" />
</body>
</html>