3

我正在尝试在几对函数图上创建一个 plot 语句循环。语句的顺序很重要，因为它会以正确的顺序创建透支。

#!/usr/bin/gnuplot -persist

datfile="overdraw.dat"
num=3
skip=40

set table datfile
g(x,t)=exp(-x**2+{0,1}*2*t*x)
set samples 501
plot [-2:2][0:5] for [ii=0:num] real(g(x,ii))
unset table

xspeed=0.1
yspeed=0.3

## this works but creates overdraw in the wrong order
#plot [-2:2] \
#  for [ii=0:num] datfile index ii u ($1+xspeed*ii):($2-yspeed*ii) not w l lt ii lw 8 \
#, for [ii=0:num] datfile index ii every skip u ($1+xspeed*ii):($2-yspeed*ii) not w p lt ii pt 7 ps 4 \
#

set macro

## this works but is cumbersome
plotstring="NaN not"
do for [ii=0:num] {
  plotstring=plotstring.sprintf(", \"%s\" index %i u ($1+xspeed*%i):($2-yspeed*%i) not w l lt %i lw 8", datfile, ii, ii, ii, ii)
  plotstring=plotstring.sprintf(", \"%s\" index %i every skip u ($1+xspeed*%i):($2-yspeed*%i) not w p lt %i pt 7 ps 4", datfile, ii, ii, ii, ii)
}
plot [-2:2] @plotstring


## this doesn't work because the for loop only applies to the first statement
#plotboth='datfile index ii u ($1+xspeed*ii):($2-yspeed*ii) not w l lt ii lw 8\
#, datfile index ii every skip u ($1+xspeed*ii):($2-yspeed*ii) not w p lt ii pt 7 ps 4'
#plot [-2:2] for [ii=0:num] @plotboth


## this gives an error message
plot [-2:2] for [ii=0:num] { \
  datfile index ii u ($1+xspeed*ii):($2-yspeed*ii) not w l lt ii lw 8\
, datfile index ii every skip u ($1+xspeed*ii):($2-yspeed*ii) not w p lt ii pt 7 ps 4 \
}

如您所见，我通过附加到包含绘图语句的字符串使其以正确的顺序工作。但是，如果能够在我的示例末尾所示的情节语句周围加上括号，那就太好了。

提交多个绘图/重新绘图语句似乎不是一种选择，因为这会在某些终端（例如 postscript）中创建页面。我也会认为 multiplot 很麻烦。也许我忽略了一种优雅的语法？

4

1 回答 1

2

我建议不要使用两条命令，一条用于线，一条用于点，而是建议一条命令用于一条带点的线，但是 - 因为有很多数据点 - 在图中跳过一些（正如你对skip变量的打算）。
根据您的数据集，我使用以下代码生成您的图： 

plot [-2:2] for [ii=0:num] datfile index ii u ($1+xspeed*ii):($2-yspeed*ii) \
  not w lp lt ii lw 8 pt 7 pi skip ps 4

我使用w lp命令（是 的缩写with linespoints）来创建一条线和点，使用命令（是pi skip的缩写pointinterval skip）来跳过40符号之间的数据点。更多信息可以在文档linespoints中找到。pointinterval

于 2013-06-12T20:13:48.857 回答