12

我有一串相互调用并引用工作簿 A 和 B 的宏。我希望第一个宏提示用户选择文档 A 和 B，这些选择成为我在各种宏。

如何使所选文档成为所有宏中的引用变量？

提前致谢！

4

3 回答 3

28

在子例程之外声明它们，如下所示：

Public wbA as Workbook
Public wbB as Workbook
Sub MySubRoutine()
    Set wbA = Workbooks.Open("C:\file.xlsx")
    Set wbB = Workbooks.Open("C:\file2.xlsx")
    OtherSubRoutine
End Sub
Sub OtherSubRoutine()
    MsgBox wbA.Name, vbInformation
End Sub

或者，您可以在子例程之间传递变量：

Sub MySubRoutine()
Dim wbA as Workbook
Dim wbB as Workbook
    Set wbA = Workbooks.Open("C:\file.xlsx")
    Set wbB = Workbooks.Open("C:\file2.xlsx")
    OtherSubRoutine wbA, wbB
End Sub
Sub OtherSubRoutine(wb1 as Workbook, wb2 as Workbook)
    MsgBox wb1.Name, vbInformation
    MsgBox wb2.Name, vbInformation
End Sub

或用于Functions返回值：

Sub MySubroutine()
    Dim i as Long
    i = MyFunction()
    MsgBox i
End Sub
Function MyFunction()
    'Lots of code that does something
    Dim x As Integer, y as Double
    For x = 1 to 1000
        'Lots of code that does something
    Next
    MyFunction = y
End Function

在第二种方法中，在OtherSubRoutine您的范围内通过参数名称wb1和wb2. 传递的变量不需要使用相同的名称，只需使用相同的变量类型即可。这为您提供了一些自由，例如，您可以在多个工作簿上循环，并且您可以将每个工作簿发送到子例程以对该工作簿执行某些操作，而无需将所有（或任何）变量公开在范围内。

关于用户表单的说明

就个人而言，我建议保留 Option Explicit所有模块和表单（这可以防止您实例化名称中包含拼写错误的变量，例如lCoutn您的意思lCount等，以及其他原因）。

如果您正在使用Option Explicit（您应该使用），那么您应该限定模块范围的变量的样式并避免歧义，并且您必须限定用户表单Public范围的变量，因为这些在同一意义上不是“公共”的。例如，i是未定义的，尽管它Public在以下范围内UserForm1：

在此处输入图像描述

您可以引用它UserForm1.i以避免编译错误，或者由于表单是New-able，您可以创建一个变量对象来包含对您的表单的引用，并以这种方式引用它：

在此处输入图像描述

注意：在上面的截图中是在另一个标准x代码模块中声明的，不会引发编译错误。如果您重复使用变量名，最好参考这个以避免歧义和可能的阴影......Public x as LongModule2.x

于 2013-05-04T12:52:48.160 回答
5

您可以考虑使用模块级别范围声明变量。模块级变量可用于该模块中的所有过程，但不可用于其他模块中的过程

有关详细信息，Scope of variables 请参阅此链接

请将以下代码复制到任何模块中，保存工作簿，然后运行代码。

这是代码的作用

  • 示例子例程设置文件夹路径和稍后的文件路径。请在运行代码之前相应地设置它们。

  • 我添加了一个函数 IsWorkBookOpen 来检查工作簿是否已经存在，然后将工作簿变量设置为工作簿名称，否则打开将相应地分配给工作簿变量的工作簿。

Dim wbA As Workbook
Dim wbB As Workbook

Sub MySubRoutine()
    Dim folderPath As String, fileNm1 As String, fileNm2 As String, filePath1 As String, filePath2 As String

    folderPath = ThisWorkbook.Path & "\"
    fileNm1 = "file1.xlsx"
    fileNm2 = "file2.xlsx"

    filePath1 = folderPath & fileNm1
    filePath2 = folderPath & fileNm2

    If IsWorkBookOpen(filePath1) Then
        Set wbA = Workbooks(fileNm1)
    Else
        Set wbA = Workbooks.Open(filePath1)
    End If


    If IsWorkBookOpen(filePath2) Then
        Set wbB = Workbooks.Open(fileNm2)
    Else
        Set wbB = Workbooks.Open(filePath2)
    End If


    ' your code here
End Sub

Function IsWorkBookOpen(FileName As String)
    Dim ff As Long, ErrNo As Long

    On Error Resume Next
    ff = FreeFile()
    Open FileName For Input Lock Read As #ff
    Close ff
    ErrNo = Err
    On Error GoTo 0

    Select Case ErrNo
    Case 0: IsWorkBookOpen = False
    Case 70: IsWorkBookOpen = True
    Case Else: Error ErrNo
    End Select
End Function

使用提示选择文件使用下面的代码。

Dim wbA As Workbook
Dim wbB As Workbook

Sub MySubRoutine()
    Dim folderPath As String, fileNm1 As String, fileNm2 As String, filePath1 As String, filePath2 As String

    Dim filePath As String
    cmdBrowse_Click filePath, 1

    filePath1 = filePath

    'reset the variable
    filePath = vbNullString

    cmdBrowse_Click filePath, 2
    filePath2 = filePath

   fileNm1 = GetFileName(filePath1, "\")
   fileNm2 = GetFileName(filePath2, "\")

    If IsWorkBookOpen(filePath1) Then
        Set wbA = Workbooks(fileNm1)
    Else
        Set wbA = Workbooks.Open(filePath1)
    End If


    If IsWorkBookOpen(filePath2) Then
        Set wbB = Workbooks.Open(fileNm2)
    Else
        Set wbB = Workbooks.Open(filePath2)
    End If


    ' your code here
End Sub

Function IsWorkBookOpen(FileName As String)
    Dim ff As Long, ErrNo As Long

    On Error Resume Next
    ff = FreeFile()
    Open FileName For Input Lock Read As #ff
    Close ff
    ErrNo = Err
    On Error GoTo 0

    Select Case ErrNo
    Case 0: IsWorkBookOpen = False
    Case 70: IsWorkBookOpen = True
    Case Else: Error ErrNo
    End Select
End Function

Private Sub cmdBrowse_Click(ByRef filePath As String, num As Integer)

    Dim fd As FileDialog
    Set fd = Application.FileDialog(msoFileDialogFilePicker)
    fd.AllowMultiSelect = False
    fd.Title = "Select workbook " & num
    fd.InitialView = msoFileDialogViewSmallIcons

    Dim FileChosen As Integer

    FileChosen = fd.Show

    fd.Filters.Clear
    fd.Filters.Add "Excel macros", "*.xlsx"


    fd.FilterIndex = 1



    If FileChosen <> -1 Then
        MsgBox "You chose cancel"
        filePath = ""
    Else
        filePath = fd.SelectedItems(1)
    End If

End Sub

Function GetFileName(fullName As String, pathSeparator As String) As String

    Dim i As Integer
    Dim iFNLenght As Integer
    iFNLenght = Len(fullName)

    For i = iFNLenght To 1 Step -1
        If Mid(fullName, i, 1) = pathSeparator Then Exit For
    Next

    GetFileName = Right(fullName, iFNLenght - i)

End Function
于 2013-05-04T15:19:09.600 回答
2

创建一个“模块”对象并在其中声明变量。与每次都必须实例化的类对象不同，模块对象始终可用。因此，“模块”中的公共变量、函数或属性将可用于 VBA 项目、宏、Excel 公式甚至 MS Access JET-SQL 查询定义中的所有其他对象。

于 2013-05-05T17:52:41.330 回答