delphi - 如何自动展开和打印 TreeView

Question

我创建了一个应用程序，它会扫描每台计算机并使用硬件、软件和更新/修补程序信息填充 TreeView：

我遇到的问题是打印，如何自动展开树视图并将所选计算机的结果发送到打印机？我当前使用的方法涉及将内容发送到画布（BMP），然后将其发送到打印机，但这并不能仅捕获屏幕上显示的整个树视图。有什么建议吗？太感谢了。

Answer 1

打印的问题TTreeView是不可见的部分没有任何东西可以绘制。（Windows 只绘制控件的可见部分，因此当您使用PrintTo或 APIPrintWindow函数时，它只有可打印的可见节点 - 未绘制的内容尚未绘制，因此无法打印。）

如果表格布局有效（没有行，只是缩进级别），最简单的方法是创建文本并将其放在 hiddenTRichEdit中，然后让TRichEdit.Print处理输出。这是一个例子：

// File->New->VCL Forms Application, then
// Drop a TTreeView and a TButton on the form.
// Add the following for the FormCreate (to create the treeview content)
// and button click handlers, and the following procedure to create
// the text content:

procedure TreeToText(const Tree: TTreeView; const RichEdit: TRichEdit);
var
  Node: TTreeNode;
  Indent: Integer;
  Padding: string;
const
  LevelIndent = 4;
begin
  RichEdit.Clear;
  Node := Tree.Items.GetFirstNode;
  while Node <> nil do
  begin
    Padding := StringOfChar(#32, Node.Level * LevelIndent);
    RichEdit.Lines.Add(Padding + Node.Text);
    Node := Node.GetNext;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  HideForm: TForm;
  HideEdit: TRichEdit;
begin
  HideForm := TForm.Create(nil);
  try
    HideEdit := TRichEdit.Create(HideForm);
    HideEdit.Parent := HideForm;
    TreeToText(TreeView1, HideEdit);
    HideEdit.Print('Printed TreeView Text');
  finally
    HideForm.Free;
  end;
end;

procedure TForm3.FormCreate(Sender: TObject);
var
  i, j: Integer;
  RootNode, ChildNode: TTreeNode;
begin
  RootNode := TreeView1.Items.AddChild(nil, 'Root');
  for i := 1 to 6 do
  begin
    ChildNode := TreeView1.Items.AddChild(RootNode, Format('Root node %d', [i]));
    for j := 1 to 4 do
      TreeView1.Items.AddChild(ChildNode, Format('Child node %d', [j]));
  end;
end;