excel - 更改excel vba中的系列

Question

我的一张纸上有一个图表，我需要在代码中更改其中的一个系列。问题是我不断收到错误 1004 消息。我环顾四周，找不到原因。这是代码：

Sheets("Charts").ChartObjects(1).Chart.SeriesCollection(1).Formula = "=G49:I" & dblResult & ")"

Answer 1

你在尝试这个吗？

Sheets("Charts").ChartObjects(1).Chart.SeriesCollection(1).Formula = _
"=SERIES(,," & "Charts!G49:I" & dblResult & ",1)"

Answer 2

我更喜欢操纵系列公式的另一种方法是仅使用SeriesCollection.

注意我是从内存中写的/未经测试，所以如果有任何问题，请告诉我！

在With块内，您需要确定用于Values、XValues、Name和的 Ranges Order，当然您可以省略不需要的部分（例如，我很少需要操作 series .Order）

Dim cht as Chart
Dim srs as Series  '# Series variable'
Dim s as Long  '# Series iterator'
Dim ws as Worksheet

Set ws = ActiveSheet
Set cht = ws.ChartObjects(1).Chart '## Modify as needed.'

For each srs in cht.SeriesCollection
    With srs
        s = s+1
        .Values = ws.Range("Some_Range_For_Values")
        .XValues = ws.Range("Range_For_XValues")
        .Name = ws.Range("Range_For_SeriesName")
        .Order = s  
    End With
Next

实际上，这是一个非常简单的示例。我经常使用这样的方法动态构建或更新图表。假设XValues在 A 列中，而系列数据在 B:F 列中，您可以执行以下操作：

Dim rngData as Range '# A range containing all of the series values & xValues'
Dim s as Long
Dim cht as Chart
Dim srs as Series
Dim ws as Worksheet

Set ws = ActiveSheet
Set cht = ws.ChartObjects(1).Chart
Set rngData = Range("A2:F10")  

'## I like to remove existing series, and then add in the new data. '
For each srs in cht.SeriesCollection
    srs.Delete
Next

'## Iterate over our range and add series back in to the chart.'

For s = 2 to rngData.Columns.Count
    Set srs = cht.NewSeries
    With srs
        .XValues = rngData.Columns(1).Address
        .Values = rngData.Columns(s).Address
        'Name = rngData.Cells(1,s).Offset(-1,0).Value
        'Order = s-1  
    End With
Next