39

我有一个JET以自动编号作为主键的表，我想知道在插入一行后如何检索该编号。我曾想过用它MAX()来检索具有最高值的行，但不确定这有多可靠。一些示例代码：

Dim query As String
Dim newRow As Integer
query = "INSERT INTO InvoiceNumbers (date) VALUES (" & NOW() & ");"
newRow = CurrentDb.Execute(query)

现在我知道这行不通，因为Execute()不会返回主键的值，但这基本上是我正在寻找的那种代码。我将需要使用新行的主键来更新另一个表中的许多行。

这样做的最简单/最易读的方法是什么？

4

5 回答 5

52

在您的示例中，因为您使用 CurrentDB 来执行您的 INSERT，所以您自己变得更加困难。相反，这将起作用：

  Dim query As String
  Dim newRow As Long  ' note change of data type
  Dim db As DAO.Database

  query = "INSERT INTO InvoiceNumbers (date) VALUES (" & NOW() & ");"
  Set db = CurrentDB
  db.Execute(query)
  newRow = db.OpenRecordset("SELECT @@IDENTITY")(0)
  Set db = Nothing

我过去常常通过打开AddOnly记录集并从那里获取 ID 来执行插入操作，但这里的效率要高得多。请注意，它不需要ADO.

于 2009-10-27T20:07:22.940 回答
41

如果DAO使用

RS.Move 0, RS.LastModified
lngID = RS!AutoNumberFieldName

如果ADO使用

cn.Execute "INSERT INTO TheTable.....", , adCmdText + adExecuteNoRecords
Set rs = cn.Execute("SELECT @@Identity", , adCmdText)
Debug.Print rs.Fields(0).Value

cn作为一个有效的 ADO 连接，@@Identity将返回 Identity在此连接上插入的最后一个（自动编号）。

请注意，这@@Identity可能很麻烦，因为最后生成的值可能不是您感兴趣的值。对于 Access 数据库引擎，请考虑VIEW连接两个表的 a ，这两个表都具有IDENTITY属性，而您INSERT INTO将VIEW. 对于 SQL Server，请考虑是否有触发器依次将记录插入到另一个也具有该IDENTITY属性的表中。

顺便说一句DMax，就好像其他人在您插入一条记录之后但在您的Dmax函数完成执行之前插入一条记录一样，那么您将获得他们的记录。

于 2009-10-27T01:27:17.380 回答
4

这是对我的代码的改编。我的灵感来自developpez.com（在页面中查找：“ Pour insérer des données, vaut-il mieux passer par un RecordSet ou par une requête de type INSERT ? ”）。他们解释（用一点法语）。这种方式比上一种要快得多。在示例中，这种方式快了 37 倍。试试看。

Const tableName As String = "InvoiceNumbers"
Const columnIdName As String = "??"
Const columnDateName As String = "date"

Dim rsTable As DAO.recordSet
Dim recordId as long

Set rsTable = CurrentDb.OpenRecordset(tableName)
Call rsTable .AddNew
recordId = CLng(rsTable (columnIdName)) ' Save your Id in a variable
rsTable (columnDateName) = Now()        ' Store your data
rsTable .Update

recordSet.Close

勒西涅

于 2009-11-27T12:35:42.563 回答
3 
Private Function addInsert(Media As String, pagesOut As Integer) As Long


    Set rst = db.OpenRecordset("tblenccomponent")
    With rst
        .AddNew
        !LeafletCode = LeafletCode
        !LeafletName = LeafletName
        !UNCPath = "somePath\" + LeafletCode + ".xml"
        !Media = Media
        !CustomerID = cboCustomerID.Column(0)
        !PagesIn = PagesIn
        !pagesOut = pagesOut
        addInsert = CLng(rst!enclosureID) 'ID is passed back to calling routine
        .Update
    End With
    rst.Close

End Function
于 2014-08-06T20:22:50.160 回答
1

上面的两个例子都不适合我。在表上打开记录集并添加记录确实可以添加记录，除了：

myLong = CLng(rs!AutoNumberField)

如果放在 rs.AddNew 和 rs.Update 之间，则返回 Null。如果放在 rs.Update 之后，它确实会返回一些东西，但它总是错误的，并且总是相同的错误值。添加新记录后直接查看表会显示与上述语句返回的值不同的自动编号字段值。

myLong = DLookup("AutoNumberField","TableName","SomeCriteria")

只要在 rs.Update 之后完成，就可以正常工作，并且还有其他可以唯一标识记录的字段。

于 2019-05-28T21:09:00.743 回答