4

我将如何编写一个通过 HTTP 发布接收文件并将其保存到文件系统的 Perl CGI 脚本？

4

4 回答 4

9

使用CGI 模块。

my $fh = $query->upload('upload_field');
while(<$fh>) {
  print SAVE_FILE $_;
}
于 2008-10-02T14:52:25.137 回答
7

请注意：无论您将如何编写它，都不要将其保存在可从您的网络服务器访问的地方。

现在直截了当：下面是我使用了一段时间来上传照片的脚本。它可能需要一些调整，但应该向您展示方式。

由于图像未上传到网络可访问目录，因此我们有单独的过程对其进行检查、调整大小、放置水印并将其放置在可以访问的位置。

 #!/usr/bin/perl -wT

use strict;
use CGI;
use CGI::Carp qw ( fatalsToBrowser );
use File::Basename;

$CGI::POST_MAX = 1024 * 5000;
my $safe_filename_characters = "a-zA-Z0-9_.-";
my $upload_dir = "/home/www/upload";

my $query = new CGI;
my $filename = $query->param("photo");
my $email_address = $query->param("email_address");

if ( !$filename )
{
 print $query->header ( );
 print "There was a problem uploading your photo (try a smaller file).";
 exit;
}

my ( $name, $path, $extension ) = fileparse ( $filename, '\..*' );
$filename = $name . $extension;
$filename =~ tr/ /_/;
$filename =~ s/[^$safe_filename_characters]//g;

if ( $filename =~ /^([$safe_filename_characters]+)$/ )
{
 $filename = $1;
}
else
{
 die "Filename contains invalid characters";
}

my $upload_filehandle = $query->upload("photo");

open ( UPLOADFILE, ">$upload_dir/$filename" ) or die "$!";
binmode UPLOADFILE;

while ( <$upload_filehandle> )
{
 print UPLOADFILE;
}

close UPLOADFILE;

print $query->header ( );
print <<END_HTML;
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "DTD/xhtml1-strict.dtd">
<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
 <head>
   <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
   <title>Thanks!</title>
 </head>
 <body>
   <p>Thanks for uploading your photo!</p>
 </body>
</html>
END_HTML
于 2008-10-02T14:49:09.090 回答
6

有关文件上传，请参阅CGI.pm 文档。

于 2008-10-02T14:50:40.227 回答
4

我将首先使用CGI并阅读CREATING A FILE UPLOAD FIELD，然后使用open创建文件并打印以写入文件。（然后关闭以关闭它）。

于 2008-10-02T15:12:35.743 回答