2

我有一个带有一堆普通 VBA 宏的 Excel 工作表。此文件不断更新并作为 Excel 加载项 (.xlam) 分发。到目前为止，我对它的工作方式感到非常满意。

现在我想添加一个运行这些宏的功能区选项卡和按钮。最初，我很高兴能找到这篇 MSDN 文章，但随后对SetCustomUIExcel（仅限 Project）似乎不存在感到沮丧，所以我无法简单地在Workbook_Open. 其他 SO 问题证实了这一点，但不提供替代方案。

我的要求：

  • 用户必须像现在一样访问宏 VBA 代码（加载项在 VBE 中显示为项目）。
  • 更新和重新分发加载项必须很容易。今天，我给他们发了一个文件来更新。
  • 我想要一个带有一些宏按钮的功能区选项卡。

有任何想法吗？

4

2 回答 2

7

这是我在 AddIn 文件上使用了一段时间的一些代码。我从别人那里继承了它，但它对我来说总是足够好用。

它应该在功能区中创建一个新工具栏AddIns：

加载项工具栏的屏幕截图

我想我复制了所有相关的代码。如果您有任何问题或遇到任何问题，请告诉我。

Option Explicit
'This module contains functions and subroutines to create Add-in menus

Public Const MenuName As String = "Menu Name"
Public Const APPNAME As String = "&Menu Name"
Private Sub Credit_Inf()

MsgBox "Created by YOUR NAME"

End Sub

Private Sub Auto_Open()

Dim NewMenuItemMacro As String
Dim NewMenuItem As String
Dim XLCommandBar As Integer
Dim NewItem As CommandBarButton
Dim ToolsMenu As CommandBarPopup
Dim NewMenu As CommandBar

NewMenuItemMacro = MenuName
NewMenuItem = APPNAME & "..."
XLCommandBar = 1 'Worksheet Menu Bar


'Delete the current menu if it exists (just in case)
On Error Resume Next
CommandBars(MenuName).Delete
On Error GoTo 0
Set NewMenu = Application.CommandBars.Add(MenuName, msoBarTop)

' .....
NewMenu.Visible = True

' Create a popup control on the bar and set its caption.
Set ToolsMenu = NewMenu.Controls.Add(Type:=msoControlPopup)
ToolsMenu.Caption = "Who built this?"
ToolsMenu.BeginGroup = True
    With ToolsMenu.Controls.Add(Type:=msoControlButton)
      .OnAction = "Credit_Inf"
      .Caption = "Find out who built this"
      .FaceId = 99
      .Style = msoButtonCaption
      .BeginGroup = False
    End With

'##Repeat ToolsMenu.Controls.Add, as necessary



End Sub


Private Sub Auto_Close()

'Delete the current menu if it exists (just in case)
On Error Resume Next
CommandBars(MenuName).Delete
On Error GoTo 0

End Sub

Private Sub EnableMenuItem(sItem As String, bEnable As Boolean)
On Error GoTo Err_EnableMenuItem

Dim NewItem As CommandBarButton
Dim NewMenu As CommandBar

Set NewMenu = Application.CommandBars(MenuName)

Set NewItem = NewMenu.FindControl(Tag:=sItem, recursive:=True)

NewItem.Enabled = bEnable

Err_EnableMenuItem:
    Resume Next

End Sub
Public Function IsWorkbookOpen() As Boolean

IsWorkbookOpen = True

If Application.Workbooks.count = 0 Then
    IsWorkbookOpen = False
End If

End Function
于 2013-04-28T15:08:41.667 回答
2

您应该能够将您的功能区 CustomUI 嵌入到您的 XLAM 文件中。我相信微软有一个工具可以帮助解决这个问题（尽管你也可以手动制作和嵌入它）。

在 OP 中，他们使用Office 自定义 UI 工具来完成此任务：

我已经尝试过这个答案的建议：在原始工作表中使用工具（我使用自定义 UI 编辑器工具）添加选项卡和按钮，然后另存为加载项。这非常适合我想要的。

这是设置：

Module mdlMyActions in MyAddin.xlsm:

 Public Sub HelloWorld(ctl As IRibbonControl)
    MsgBox("Hello, world!")
End Sub

插入 MyAddin.xlsm 的 XML：

 <customUI xmlns="http://schemas.microsoft.com/office/2009/07/customui">
  <ribbon startFromScratch="false">
    <tabs>
      <tab id="tabMyTab" label="My Tab">
        <group id="grpMyGroup" label="My Group">
          <button id="btnHelloWorld" label="Hello World"
                  imageMso="HappyFace" size="large" onAction="HelloWorld" />
        </group>
      </tab>
    </tabs>
  </ribbon>
</customUI>

请注意，这都是在保存为加载项之前的全部内容。一旦保存为加载项并安装到 Excel 中，加载项就可以完美运行。

于 2013-04-28T16:32:02.037 回答