1

我需要制作列表的列表，它将是某种矩阵，大小为 N x N，对于相同的 N，我不知道如何声明列表的所有元素必须是具有 N 个元素的列表？

4

2 回答 2

3

考虑：

n_matrix(N, Rows) :-
        length(Rows, N),
        maplist(length_list(N), Rows).

length_list(L, Ls) :- length(Ls, L).

例子：

?- n_matrix(2, Rows).
Rows = [[_G294, _G297], [_G300, _G303]].

或者，您可以使用findall/3：

n_matrix(N, Rows) :-
        findall(Row, (between(1,N,_),length(Row, N)), Rows).
于 2013-04-27T09:28:19.400 回答
1

好吧，制作长度为 N 的列表的最简单方法是length/2：

?- length(L, 5).
L = [_G1233, _G1236, _G1239, _G1242, _G1245].

您可以轻松地多次应用它以获得您想要的结果：

make_matrix(N, M) :- once(make_matrix(0, N, M)).

make_matrix(N, N, []).
make_matrix(I, N, [Row|Rows]) :-
    length(Row, N),
    I1 is I + 1,
    make_matrix(I1, N, Rows).

用过的：

?- make_matrix(5, M).
M = [[_G479, _G482, _G485, _G488, _G491], 
     [_G497, _G500, _G503, _G506, _G509], 
     [_G515, _G518, _G521, _G524, _G527], 
     [_G533, _G536, _G539, _G542, _G545], 
     [_G551, _G554, _G557, _G560|...]].

可能有更优雅的方法可以做到这一点。

编辑：这里有一个更通用的方法来做到这一点，没有削减和clpfd：

:- use_module(library(clpfd)).

matrix(1,M,[L]) :- length(L, M).
matrix(N,M,[Row1|L]) :- 
  N #> 1, 
  N0 #= N-1,
  length(L, M),
  matrix(N0,M,L).
于 2013-04-26T22:14:01.660 回答