2

我认为我的 Perl 生锈了 :)

以下脚本应该遍历包含特定用户的 LDAP 记录的文本文件目录，以提取特定信息。如果文件中不存在“productfamily”属性，我遇到了从哈希引用中删除“组”哈希键的问题。

#!/bin/perl

use strict;
use warnings;
use Data::Dumper;
use File::Basename;

sub extract_val {
    my $line = shift;
    return (split /\:/, $line)[1];
}

my @ldif_files = <tmp/*.ldif>;
my $line_ctr = 0;
my @record_ctr;

for my $ldif_file (@ldif_files) {

    open my $fh,'<', $ldif_file or die "Cannot open file: $!";
    my @contents = <$fh>;
    close $fh;

    my $user_record = {
       'file'    => basename $ldif_file,
       'group'   => 'BP',
       'uid'     => '',
       'fname'   => '',
       'lname'   => '',
       'company' => '',
    };

    for my $line (@contents){
        chomp $line;
        $user_record->{'uid'}     = extract_val($line) if $line =~ /^uid\:/;
        $user_record->{'fname'}   = extract_val($line) if $line =~ /^givenname\:/;
        $user_record->{'lname'}   = extract_val($line) if $line =~ /^sn\:/;
        $user_record->{'company'} = extract_val($line) if $line =~ /^o\:/;
        $user_record->{'group'}   = 'EU' if $line =~ /^productfamily\:/;
    }

    print Dumper $user_record;

    last if $line_ctr++ == 10;
}

输出示例

这是输出中的两个代表性样本。

如果 LDAP 记录中存在 productfamily 属性，则存在“组”哈希键。

$VAR1 = {
    'group' => 'EU',
    'uid' => 'abcdef',
    'lname' => 'SMITH',
    'fname' => 'JOHN',
    'file' => 'abcdef.ldif',
    'company' => 'Some Company'
    };

如果 LDAP 记录中不存在 productfamily 属性，则缺少“组”哈希键。

$VAR1 = {
    'uid' => 'uvwxyz',
    'lname' => 'Bar',
    'fname' => 'Foo',
    'file' => 'uvwxyz.ldif',
    'company' => 'Another Company'
    };

Perl 版本是 Solaris 5.9 上的 5.8.5。

大约有 6000 个文件，但我将循环迭代次数限制为 10 次，因为问题出现在我的数据文件的早期。

4

1 回答 1

4

basename没有原型，所以它会吞掉你所有的哈希条目。你写的相当于

my $user_record = {
   'file'    => basename($ldif_file,
                         'group'   => 'BP',
                         'uid'     => '',
                         'fname'   => '',
                         'lname'   => '',
                         'company' => ''),
};
于 2013-04-25T21:54:01.440 回答