delphi - Delphi 如何在 TCanvas 上快速绘制二维 TColor 数组？

Question

我有一个 TColor 的二维数组。而且我还有一个 TCanvas。我怎样才能比使用for循环更快地在画布上绘制此颜色图？

例如：

type
  T2DAr = array of array of TColor;

var
  ar: T2DAr;
  Form1: TForm; // mainform

function main;
var x, y: integer;
begin
{filling array with colors as a 10x10}

for x := 0 to length(ar)-1 do
for y := 0 to length(ar[x])-1 do
Form1.Canvas.Pixels[x, y] := ar[x, y];
end;

这种方式工作太慢了。我需要一个更快的算法。

Answer 1

这已经回答了很多次了。答案是：使用scanlines 而不是非常慢的Pixels属性。例子：

function CreateBitmapReallyFast: TBitmap;
const
  WHITE: TRGBTriple = (rgbtBlue: 255; rgbtGreen: 255; rgbtRed: 255);
  BLACK: TRGBTriple = (rgbtBlue: 0; rgbtGreen: 0; rgbtRed: 0);
var
  y: Integer;
  scanline: PRGBTriple;
  x: Integer;
begin
  result := TBitmap.Create;
  result.SetSize(1920, 1080);
  result.PixelFormat := pf24bit;
  for y := 0 to result.Height - 1 do
  begin
    scanline := result.ScanLine[y];
    for x := 0 to result.Width - 1 do
    begin
      if odd(x) then
        scanline^ := WHITE
      else
        scanline^ := BLACK;
      inc(scanline);
    end;
  end;
end;

更酷：

with scanline^ do
begin
  rgbtBlue := Random(255);
  rgbtGreen := Random(255);
  rgbtRed := Random(255);
end;

尝试一下：

procedure TForm1.FormPaint(Sender: TObject);
var
  bm: TBitmap;
begin
  bm := CreateBitmapReallyFast;
  try
    Canvas.Draw(0, 0, bm);
  finally
    bm.Free;
  end;
end;

当然，如果你有一个TRGBTripleor的（打包的）数组TRGBQuad，并且位图的像素格式相同，你可以简单地Move将内存中的数据从数组到位图的扫描线。