arrays - 如何使用值数组来限制 perl 中的 for 循环？

Question

我知道这个问题相当模糊，但我希望解释的空间可以帮助阐明，这是我整天绞尽脑汁但无法通过搜索找到任何建议的问题。

基本上我有一个数组@cluster，我试图用它来使迭代器 $x 跳过位于该数组中的值。数组的大小会有所不同，所以不幸的是，我不能（相当残忍地）做出 if 语句来适应所有情况。

通常，当我需要使用标量值执行此操作时，我会这样做：

for my $x (0 .. $numLines){
    if($x != $value){
        ...
    }
}

有什么建议吗？

Answer 1

你可以做：

my @cluster = (1,3,4,7);
outer: for my $x (0 .. 10){
    $x eq $_ and next outer for @cluster;
    print $x, "\n";
}

使用 Perl 5.10，您还可以：

for my $x (0 .. 10){
    next if $x ~~ @cluster;
    print $x, "\n";
}

或者更好地使用哈希：

my @cluster = (1,3,4,7);
my %cluster = map {$_, 1} @cluster;
for my $x (0 .. 10){
    next if $cluster{$x};
    print $x, "\n";
}

Answer 2

嗯...如果您要跳过行，为什么不直接使用该标准而不是记住需要过滤掉的行？

该grep函数是过滤列表的强大构造：

my @array = 1 .. 10;

print "$_\n" for grep { not /^[1347]$/ } @array;  # 2,5,6,8,9,10
print "$_\n" for grep {     $_ % 2     } @array;  # 1,3,5,7,9

my @text = qw( the cat sat on the mat );

print "$_\n" for grep { ! /at/ } @text;           # the, on, the

更少的混乱，更多的 DWIM！

Answer 3

你的意思是这样的吗：

for my $x (0 .. $numLines){
    my $is_not_in_claster = 1;
    for( @claster ){
         if( $x == $_ ){
             $is_not_in_claster = 0;
             last;
         }
    }
    if( $is_not_in_claster ){
        ...
    }
}

?